vb.net listviewから重複を削除する最速の方法は？

Question

誰かがリストビューから重複を削除するためのより迅速で優れた方法を持っていますか？私は現在、このようにしています：アイテムをアルファベット順にソートし、次にアイテムをチェックし、それを上のアイテムと比較します。

これは時間がかかります。Excelシートに20.000レコードを入力して重複を削除すると、数ミリ秒かかりますが、このコードではvb.netの20.000項目を確認するのに数時間かかることがあります。誰かがより速い方法を知っていますか？

Dim max As Integer = ListView2.Items.Count 
    Dim i As Integer = 0 

    For Each item As ListViewItem In ListView2.Items 

     If i = max Then 
      Exit For 
     End If 

     If i > 0 Then 

      If item.Text = ListView2.Items(i - 1).Text Then 
       max -= 1 
       item.Remove() 
       i -= 1 
      End If 
     End If 

     i += 1 

     Label4.Text = "Total domains: " & ListView2.Items.Count 

    Next 

Answer 1

HashSetを使用してください。これはユニークな値のみを受け入れます。

Dim itemsText = ListView2.Items.Cast(Of ListViewItem).Select(Function(item) item.Text) 
Dim uniquesValues As HashSet(Of String) = New HashSet(Of String)(itemsText) 

はその後HashSetからListViewに項目を設定します。

Answer 2

ここでは、item.Textに基づいて異なるアイテムを取得し、アイテムを並べ替えるためのLinqベースのソリューションです。ソートが不要な場合は、OrderByの部分を削除できます。

Private Shared Sub RemoveDuplicatesAndSort(lv As ListView) 
    Dim distictItems As ListViewItem() = lv.Items.Cast(Of ListViewItem)().Distinct(New LVItemComparer()).OrderBy(Function(item As ListViewItem) item.Text).ToArray 
    lv.BeginUpdate() ' suppress screen updates 
    lv.Items.Clear() 
    lv.Items.AddRange(distictItems) 
    lv.EndUpdate() 
End Sub 

Private Class LVItemComparer : Implements IEqualityComparer(Of ListViewItem) 
    Public Function Equals1(x As ListViewItem, y As ListViewItem) As Boolean Implements IEqualityComparer(Of ListViewItem).Equals 
     Return x.Text.Equals(y.Text) 
    End Function 

    Public Function GetHashCode1(obj As ListViewItem) As Integer Implements IEqualityComparer(Of ListViewItem).GetHashCode 
     Return obj.Text.GetHashCode 
    End Function 
End Class