保護を解除し、すべてのフォルダ内のすべてのバイナリワークブック内のシートとそれらを保存し、保護されていない

Question

• 私は.xlsbワークブックのフォルダを持っています。
• 各ブックには5枚のシートがあり、すべてがパスワードで保護されています。
• パスワードはすべてのシート、すべてのワークブックに共通です。
• ワークブック自体にはパスワードがありません。

すべてのブックのすべてのシートの保護を解除し、保護されていないとして保存するにはどうすればよいですか？

私は次のコードを見つけましたが、必要な処理を実行できません（アクティブなワークブックのみで動作します）。このような

Sub unprotect_all_sheets() 
On Error Goto booboo 
unpass = InputBox("password") 
For Each Worksheet In ActiveWorkbook.Worksheets 
Worksheet.Unprotect Password:=unpass 
Next 
Exit Sub 
booboo: MsgBox "There is s problem - check your password, capslock, etc." 
End Sub 

Answer 1

何か：

はどれシートの保護を解除するために失敗したがすぐに窓

Sub LoopThroughFiles() 
    Dim StrFile As String 
    Dim Wb As Workbook 
    Dim ws As Worksheet 
    Dim strFol As String 
    Dim strPass As String 

    'password 
    strPass = "tested" 

    With Application 
     .ScreenUpdating = False 
     .EnableEvents = False 
     .DisplayAlerts = False 
    End With 

    'folder to work in 
    strFol = "c:\temp\" 

    StrFile = Dir(strFol & "*.xls*") 
    Do While Len(StrFile) > 0 
     Set Wb = Workbooks.Open(strFol & StrFile) 
      For Each ws In Wb.Worksheets 
      On Error Resume Next 
      ws.Unprotect strPass 
      If Err.Number <> 0 Then Debug.Print strFol & StrFile & " " & ws.Name 
      On Error GoTo 0 

     Next 
     Wb.Save 
     Wb.Close 
     StrFile = Dir 
    Loop 

    With Application 
     .ScreenUpdating = True 
     .EnableEvents = True 
     .DisplayAlerts = True 
    End With 
End Sub