シンプルなXSLTテキストの置換

Question

私はXMLのテキストを置き換える、よりシンプルで洗練された方法を探しています。ソースXMLのような場合：

<A> 
<B> 
    <Name>ThisOne</Name> 
    <Target>abc</Target> 
</B> 
<B> 
    <Name>NotThisOne</Name> 
    <Target>abc</Target> 
</B> 
<B> 
    <Name>ThisOne</Name> 
    <Target>def</Target> 
</B> 
</A> 

私は「XYZ」に「ThisOne」の名前を持つすべてのターゲット要素のテキストを変更したいです。

結果は次のようになります。私は、これは< XSLで行うことができることを考えていた

<?xml version="1.0" encoding="ISO-8859-1"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="B/Target"> 
    <xsl:choose> 
     <xsl:when test="../Name/text()='ThisOne'"><Target>xyz</Target></xsl:when> 
     <xsl:otherwise><Target><xsl:value-of select="text()"/></Target></xsl:otherwise> 
    </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

：テンプレートマッチ= "B /ターゲット/テキスト（）

<A> 
<B> 
    <Name>ThisOne</Name> 
    <Target>xyz</Target>  <-- Changed. 
</B> 
<B> 
    <Name>NotThisOne</Name> 
    <Target>abc</Target> 
</B> 
<B> 
    <Name>ThisOne</Name> 
    <Target>xyz</Target>  <-- Changed. 
</B> 
</A> 

私はこれを達成">だから、要素全体ではなくテキストだけを置き換えることができましたが、残りの部分はわかりませんでした。

ありがとうございます。

Answer 1

このスタイルシート：あなたのXML入力を使用して

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="B[Name='ThisOne']/Target/text()"> 
    <xsl:text>xyz</xsl:text> 
    </xsl:template> 

</xsl:stylesheet> 

は生成します。

<A> 
    <B> 
    <Name>ThisOne</Name> 
    <Target>xyz</Target> 
    </B> 
    <B> 
    <Name>NotThisOne</Name> 
    <Target>abc</Target> 
    </B> 
    <B> 
    <Name>ThisOne</Name> 
    <Target>xyz</Target> 
    </B> 
</A> 

Answer 2

これは、あなたがしなければならないのです。

<xsl:template match="@*|node()"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="B/Target[../Name='ThisOne']"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*"/> 
    <xsl:text>xyz</xsl:text> 
    </xsl:copy> 
</xsl:template> 

最初のテンプレートは、「恒等変換であります入力をそのまま出力にコピーします。 2番目は変更したい特定のターゲットと一致し、タグと属性をコピーして、目的のテキストを置き換えます。

Answer 3

<?xml version="1.0" encoding="iso-8859-1"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:cds="cds_dt" exclude-result-prefixes="cds"> 
    <!-- Identity transfrom - just copy what doesn't need changing --> 
    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <!-- a rule for what does need changing --> 
    <!-- Change all Target nodes whose parent has a child of Name equal to ThisOne --> 
    <xsl:template match="/A/B[Name='ThisOne']/Target"> 
     <Target>xyz</Target> 
    </xsl:template> 
</xsl:stylesheet>