UNION内のSPARQL BINDが遅すぎる

Question

私はIMDb IDを与えられているので、Wikidataからその映画の監督と俳優のリストを取得したいと思います。

問題は、ディレクターとアクターの両方のクエリーを1つのカラムに結合し、ディレクターまたはアクターの役割を持つ新しいカラムを提供することです。

私はIMDb IDからムービーエンティティを取得してから、そのムービーのすべてのディレクターを取得してから、そのムービーのすべてのアクターを取得し、それらを一緒に結合して新しいカラム（？ ）をロールと関連付けます。

これは私が持っているものです。

PREFIX p: <http://www.wikidata.org/prop/> 
PREFIX ps: <http://www.wikidata.org/prop/statement/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 
SELECT ?person ?personLabel ?role ?imdb WHERE 
{ 
    ?movie wdt:P345 "tt0110912" . 
    { ?movie p:P57 ?cast . 
    ?cast ps:P57 ?person . 
    BIND("director" as ?role) . 
    } UNION { 
    ?movie p:P161 ?cast . 
    ?cast ps:P161 ?person . 
    BIND("actor" as ?role) . } 

    ?person wdt:P345 ?imdb . 
    OPTIONAL { ?cast prov:wasDerivedFrom ?ref . } 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } 
} 
GROUP BY ?person ?personLabel ?role ?imdb 
ORDER BY DESC(?role) 
LIMIT 100 

この作品と私が望む結果を与える、問題はそれが10secsほどかかります。 BINDを即座に削除しても、ロールを持つ列は得られません。

ありがとうございます。ありがとうございます。

Answer 1

私は値の代わりにバインドと組合のを使用して、これを記述します。そのアイデアは、プロパティが1つのこと、次にロールが1つ、プロパティが別の場合はロールが別のものであると言っているということです。

お使いの場合には

select ?owner ?pet ?petType { 
    values (?hasPet ?petType) { 
    (:hasCat "cat") 
    (:hasDog "dog") 
    } 
    ?owner ?hasPet ?pet 
} 

、これは次のようになります：のようなものである値とすることを行う簡単な方法

PREFIX p: <http://www.wikidata.org/prop/> 
PREFIX ps: <http://www.wikidata.org/prop/statement/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 
SELECT ?person ?personLabel ?role ?imdb WHERE 
{ 
    ?movie wdt:P345 "tt0110912" . 

    values (?p ?ps ?role) { 
    (p:P161 ps:P161 "actor") 
    (p:P57 ps:P57 "director") 
    } 
    ?movie ?p ?cast . 
    ?cast ?ps ?person . 

    ?person wdt:P345 ?imdb . 
    OPTIONAL { ?cast prov:wasDerivedFrom ?ref . } 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } 
} 
GROUP BY ?person ?personLabel ?role ?imdb 
ORDER BY DESC(?role) 
LIMIT 100 

私はquery.wikidata.orgでこれを実行すると、ほぼ即時に35 resultsを生成します。

Answer 2

BINDは、クエリオプティマイザにいくつかの問題が発生していると思います。あなたはすなわち

は（あなたが ?ref変数をしない場合、あなたは UNION句で ?castを取得するために、トリプル・パターンを省略することができます。）

PREFIX p: <http://www.wikidata.org/prop/> 
PREFIX ps: <http://www.wikidata.org/prop/statement/> 
PREFIX wdt: <http://www.wikidata.org/prop/direct/> 
SELECT ?person ?personLabel ?role ?imdb WHERE 
{ 
    ?movie wdt:P345 "tt0110912" . 
    ?person wdt:P345 ?imdb . 
    { 
    ?movie p:P57 ?c1 . ?c1 ps:P57 ?person . 
    ?movie p:P57 ?cast . 
    } UNION { 
    ?movie p:P161 ?c2 . ?c2 ps:P161 ?person . 
    ?movie p:P161 ?cast . 
    } 
    BIND(IF(bound(?c1), "director", "actor") as ?role) 

    OPTIONAL { ?cast prov:wasDerivedFrom ?ref . } 
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". } 
} 
GROUP BY ?person ?personLabel ?role ?imdb 
ORDER BY DESC(?role) 
LIMIT 100 

、UNION句の外で役割をバインドするための代替として試すことができます