オプションを選択するとColdFusionオプションが削除される

Question

ColdFusionコードに問題があります。私はcfloopを使用してオプションを設定する単純なHTML選択フォームを作成しようとしています。それは動作し、オプションを選択すると、そのオプションがdbから取り出されます。一度それを行うと、以前に選択されたオプションだけが利用可能です。私は間違って何をしていますか？

<!--- Query the DataBase ---> 
<cfparam name="url.colors" default=""> 
<cfif structKeyExists(form, "colordb")> 
    <cfset url.colordb = form.colordb> 
</cfif> 
<cfquery datasource="bentest" name="colors"> 
    SELECT * 
    FROM color_codes 
    <cfif structKeyExists(url,"colordb") and isNumeric(url.colordb)> 
     WHERE id=#url.colordb# 
    </cfif> 
</cfquery> 
<!--- Add Selector for user to select a color ---> 
<div class="selector"> 
    <cfoutput> 
     <form action="?contentId=colorPickdb" name="clr" method="post" class="clr"> 
      <select class="clr" name="colordb" onChange="submit();"> 
       <option selected>Select A Color!</option> 
       <cfloop query="colors"> 
        <option value="#colors.id#">#colors.color#</option> 
       </cfloop> 
      </select> 
     </form> 
    </cfoutput> 
</div> 
<div class="dump"> 
    <!--- Output results of Query ---> 
    <p><cfif structKeyExists(form, "colordb")> 
     <cfoutput query="colors"> 
      #colors.color# <br> 
      #colors.hexvalue# <br><br> 
     </cfoutput> 
     </cfif> 
     <br> 
    </p> 
</div> 

Answer 1

ここでは、クエリのクエリを使用できます。

<!--- Query the DataBase ---> 
<cfparam name="url.colors" default=""> 
<cfquery datasource="bentest" name="colors"> 
    SELECT * 
    FROM color_codes 
</cfquery> 
<!--- Add Selector for user to select a color ---> 
<div class="selector"> 
    <cfoutput> 
     <form action="?contentId=colorPickdb" name="clr" method="post" class="clr"> 
      <select class="clr" name="colordb" onChange="submit();"> 
       <option selected>Select A Color!</option> 
       <cfloop query="colors"> 
        <option value="#colors.id#">#colors.color#</option> 
       </cfloop> 
      </select> 
     </form> 
    </cfoutput> 
</div> 
<div class="dump"> 
    <!--- Output results of Query ---> 
    <p> 
     <cfif structKeyExists(form, "colordb")> 
      <cfquery dbtype="query" name="colorSelected"> 
       SELECT * 
       FROM colors 
       WHERE id=#form.colordb# 
      </cfquery> 
      <cfoutput query="colorSelected"> 
       #colorSelected.color# <br> 
       #colorSelected.hexvalue# <br><br> 
      </cfoutput> 
     </cfif> 
     <br> 
    </p> 
</div>