Excel VBA - オートメーションエラー

Question

画像のリストとそのサイズ（幅/高さ）をspreadshitするマクロを使用しようとしています。私はマクロを実行すると数秒間実行され、フォルダ内の2000個のイメージのうち116個のレコードを取得し、オートメーションエラーでクラッシュするだけではありません。

私はfixexを適用するために調査し、私はアップデート、repoarオフィスなどで見つけることができ、何もこの問題を修正していません。

Public Sub Image() 
Dim strFile As String 
Dim stdPic As StdPicture 
Dim lngWidth As Long 
Dim lngHeight As Long 
Dim strPath As String 
Dim lngRow As Long ' Made this a Long just in case you have a LOT of pictures 

strPath = "C:\IMAGES\" 

' Get all files (we'll filter the results below) 
' strFile = Dir$(strPath & "\*.jpg") 
    strFile = Dir$(strPath & "\*.*") 

' Find the last row in Col A 
lngRow = Range("A10000").End(xlUp).Row 

Do While Len(strFile) 
    ' Select the picture types you want. In this case jpg, bmp and png 
    If UCase$(Right$(strFile, 4)) = ".JPG" Or _ 
     UCase$(Right$(strFile, 4)) = ".BMP" Or _ 
     UCase$(Right$(strFile, 4)) = ".PNG" Then 
     Set stdPic = LoadPicture(strPath & "\" & strFile) 
     lngRow = lngRow + 1 
     Range("A" & lngRow).Value = strFile 
     Range("B" & lngRow).Value = Round(stdPic.Width/26.4583) 
     Range("C" & lngRow).Value = Round(stdPic.Height/26.4583) 
    End If 
    strFile = Dir$ 
Loop 
End Sub 

誰もがアイデア、なぜこれが起こっているがありますか？

Answer 1

これはトリックを行う必要があります。

いくつかのコメント：

• は二重のバックスラッシュを避け、あなたはstrPathにそれを持っていただけでなく、strFileの割り当てでそれを使用しました。
• 画像の読み込みに失敗した場合は、stdPicをクリアし、 エラー処理を無効にし、stdPicを読み込み、エラー処理を再度有効にし、 画像が正しく読み込まれるようにstdPicが存在するかどうかを確認します。それは しなかった場合、それはエントリを取得しません。 が間違って破損する可能性があることに対処するときは、それが正常であることを確認することが最善であると が期待通りに機能しています。以下

改正サブ：

Public Sub Image() 
Dim strFile As String 
Dim stdPic As StdPicture 
Dim lngWidth As Long 
Dim lngHeight As Long 
Dim strPath As String 
Dim lngRow As Long ' Made this a Long just in case you have a LOT of pictures 

strPath = "C:\IMAGES" 

' Get all files (we'll filter the results below) 
' strFile = Dir$(strPath & "\*.jpg") 
    strFile = Dir$(strPath & "\*.*") 

' Find the last row in Col A 
lngRow = Range("A10000").End(xlUp).Row 

Do While Len(strFile) 
    ' Select the picture types you want. In this case jpg, bmp and png 
    If Left(strFile, 1) <> "~" And _ 
     (UCase$(Right$(strFile, 4)) = ".JPG" Or _ 
     UCase$(Right$(strFile, 4)) = ".BMP" Or _ 
     UCase$(Right$(strFile, 4)) = ".PNG") Then 
      Set stdPic = Nothing 
      On Error Resume Next 
       Set stdPic = LoadPicture(strPath & "\" & strFile) 
      On Error GoTo 0 
      If Not stdPic Is Nothing Then 
       lngRow = lngRow + 1 
       Range("A" & lngRow).Value = strFile 
       Range("B" & lngRow).Value = Round(stdPic.Width/26.4583) 
       Range("C" & lngRow).Value = Round(stdPic.Height/26.4583) 
      End If 
    End If 
    strFile = Dir$ 
Loop 
End Sub