Delphiで配列プロパティを正しく宣言するにはどうすればよいですか？

Question

私はTStringListのすべての項目を配列に作成しようとしていますが、このサイズは前記TStringList内の項目の数によって異なります。

私の構文が間違っていて、私が望むのはおそらく動的配列なので、[0..100]はおそらく間違っていますが、オンラインで代替構文を見つけることができませんでした。

ProductAvailabilityResult = Class(TRemotable) 
private 
    FResultArray : array[1..100] of string; 
published 
    property ResultArray[Index: Integer]: array of string read FResultArray write FResultArray; 
End; 

これは私がそれを呼び出して作成する方法です。 conditionList私のTStringList私は自分の配列に移入します。

for I := 0 to conditionList.Count - 1 do 
begin 
    aProductAvailabilityResult.ResultArray[I] := conditionList[I]; 
end; 

あなたがまたは私がやっているものに代替の提案があってもなくてもよい場合には、SOAPサーバ上で結果を送信するWebサービスアプリですので、このセットアップの理由は、私は私は思いませんPHP/SoapクライアントはTStringListを読むことができるので、最初に配列に渡す必要があります。

お知らせください、ありがとうございます！

Answer 1

文法上の誤りがありますが、array propertyと宣言しました。しかし、あなたは動的配列であるプロパティが必要であるという質問とコメントを述べています。これは配列プロパティとは異なります。

そうのような動的配列のプロパティを宣言します。

type 
    ProductAvailabilityResult = class(TRemotable) 
    private 
    FResultArray: TArray<string>; 
    published 
    property ResultArray: TArray<string> read FResultArray write FResultArray; 
    end; 

はこのようにそれを読み込む：配列プロパティを宣言するための

var 
    i: Integer; 
    List: TStringList; 
    par: ProductAvailabilityResult; 
    arr: TArray<string>; 
.... 
List := ...; 
par := ...; 
SetLength(arr, List.Count); 
for i := 0 to List.Count-1 do 
    arr[i] := List[i]; 
par.ResultArray := arr; 

Answer 2

あなたの構文は近いですが、getter/setterメソッドを使用する必要があります直接のフィールドアクセスではなく、配列プロパティをpublishedとして宣言することはできません。

type 
    ProductAvailabilityResult = class(TRemotable) 
    private 
    FResultArray : array of string; 
    function GetResultArray(Index: Integer): string; 
    function GetResultArrayCount: Integer; 
    procedure SetResultArray(Index: Integer; const Value: string); 
    procedure SetResultArrayCount(Value: Integer); 
    public 
    property ResultArray[Index: Integer]: string read GetResultArray write SetResultArray default; 
    property ResultArrayCount: Integer read GetResultArrayCount write SetResultArrayCount; 
    end; 

function ProductAvailabilityResult.GetResultArray(Index: Integer): string; 
begin 
    Result := FResultArray[Index]; 
end; 

function ProductAvailabilityResult.GetResultArrayCount: Integer; 
begin 
    Result := Length(FResultArray); 
end; 

procedure ProductAvailabilityResult.SetResultArray(Index: Integer; const Value: string); 
begin 
    FResultArray[Index] := Value; 
end; 

procedure ProductAvailabilityResult.SetResultArrayCount(Value: Integer); 
begin 
    SetLength(FResultArray, Value); 
end; 

は、その後、あなたはこれを行うことができます。

type 
    ProductAvailabilityResult = class(TRemotable) 
    private 
    ... 
    public 
    procedure AssignStrings(AStrings: TStrings); 
    ... 
    end; 

procedure ProductAvailabilityResult.AssignStrings(AStrings: TStrings); 
var 
    I: Integer; 
begin 
    SetLength(FResultArray, AStrings.Count); 
    for I := 0 to AStrings.Count - 1 do 
    FResultArray[I] := AStrings[I]; 
end; 

aProductAvailabilityResult.AssignStrings(conditionList);