Excelのセルに画像を挿入する

Question

私はこの質問がいくつかの方法で複数回尋ねられていることを知っていますので、これが重複して表示された場合は重複としてマークしてください。

私はExcelで目録を作成したいと思います。セルに画像を挿入するには、すばやい方法が必要です。私はあなたがコメントを挿入することによってこれを行うことができますが、それはちょうど非常に遅いプロセスです。

これは、VBAや、フォルダの画像を目的のセルに追加するスクリプトで行うことができますか？

Answer 1

は、以下のコードを見てみましょう：

Public Sub sampleCode() 
Dim WB As Workbook 
Dim targetWS As Worksheet 
Dim targetCell As Range 
Dim imageCounter As Long 
Dim sourceFolderPath As String 
Dim dirStr As String 
Dim imageObj As Picture 

Set WB = ThisWorkbook 
Set targetWS = WB.Sheets(1) 

With Application.FileDialog(msoFileDialogFolderPicker) 
    .Title = "Select the folder that contains the pictures." 
    .Show 
    sourceFolderPath = .SelectedItems(1) & "\" 
End With 

dirStr = Dir(sourceFolderPath) 
Do Until dirStr = "" 
    If Right(dirStr, 3) = "png" Or Right(dirStr, 3) = "jpg" Then 
     imageCounter = imageCounter + 1 
     Set imageObj = targetWS.Pictures.Insert(sourceFolderPath & dirStr) 
     Set targetCell = targetWS.Range("A" & imageCounter) 
     With targetCell 
      .ColumnWidth = imageObj.Width/5.4636515404462 
      .RowHeight = imageObj.Height 
      imageObj.Top = .Top 
      imageObj.Left = .Left 
     End With 
    End If 
    dirStr = Dir 
Loop 

End Sub 

よろしく、 TheSilkCode