Androidスタジオでjcenter（）のデフォルト値を変更するにはどうすればよいですか？

Question

はSOを参照してください：Peer not authenticated while importing Gradle project in eclipse

をエラーを排除するには、次のように私はbuild.gradle編集する必要があり、新規のAndroid Studioプロジェクトに：

//jcenter() 
    jcenter { 
     url "http://jcenter.bintray.com/" 
    } 

元jcenter（）コメントアウトする必要があります。確かにどこかデフォルト値を変更する場所がありますので、この方法で各プロジェクトを変更する必要はありません。

Answer 1

私は以下の貼り付け、これを行うためのVBScriptファイルを作って、次のパスに処理：新しいプロジェクトを作成するときにjcenterと\プログラムファイル\のAndroid \のAndroid Studioの\プラグイン

これ以上の問題：Cを。

const ToRead = 1 
const ToWrite = 2 
const ToAppend = 8 
edit_path = "" 
if wscript.arguments.count > 0 then edit_path = trim(wscript.arguments.item(0)) 
if left(edit_path,1) = """" then edit_path = mid(edit_path,2) 
if right(edit_path,1) = """" then edit_path = left(edit_path,len(edit_path)-1) 
if len(edit_path) = 0 then 
    msgbox "Drag and drop the folder onto this script file to process it" 
    wscript.quit 
    end if 
set fso = createobject("Scripting.FileSystemObject") 
dim reader,writer 
if not fso.folderexists(edit_path) then 
    msgbox "folder not found" 
    wscript.quit 
    end if 
count = 0 
if msgbox("The following path will be processed" & vbcrlf & _ 
      edit_path & vbcrlf & vbcrlf & _ 
      "Continue?",vbyesno) = vbyes then 
    scan edit_path 
    msgbox count & " files edited" 
    end if 

sub scan(path) 
    set files = fso.getfolder(path).files 
    for each f in files 
    if lcase(right(f.name,11)) = ".gradle.ftl" then edit_file path & "\" & f.name 
    next 
    set folders = fso.getfolder(path).subfolders 
    for each f in folders : scan path & "\" & f.name : next 
end sub 

sub edit_file(file_name) 
    set reader = fso.opentextfile(file_name,ToRead) 
    a = "" 
    if not reader.atendofstream then a = reader.readall 
    reader.close 
    found = false 
    sw = true 
    while sw 
    sw = false 
    p = instr(1,a," jcenter()" & vblf,vbtextcompare) 
    if p > 0 then 
     q = instrrev(a,vblf,p) 
     if q > 0 then 
     sw = true 
     found = true 
     spacing = p - q + 1 
     a = left(a,q) & space(spacing) & "//jcenter()" & vblf & _ 
         space(spacing) & "jcenter {" & vblf & _ 
         space(spacing) & " url ""http://jcenter.bintray.com/""" & vblf & _ 
         space(spacing) & "}" & mid(a,p+11) 
     end if 
     end if 
    wend 
    if found then 
    count = count + 1 
    fso.movefile file_name,file_name & ".save" 
    set writer = fso.createtextfile(file_name) 
    writer.write a 
    writer.close 
    end if 
end sub