Excel VBAはすべてのシートをループしてシートの色を変更します

Question

ブック内のすべてのシートをループし、シートの色を下の順に変更するExcel VBAが必要です。シートがなくなるまで3,5,6,12,3,5,6,12,3,5,6,12回繰り返しパターンを繰り返す。 以下のコードはランダムな色でそれらを変更する作業ですが、私は上記のパターンが必要です。

Sub sbColorAllSheetTab() 
'Declaration 
Dim iCntr, sht 
'This will hold the colorIndex number 
iCntr = 2 
'looping throgh the all the sheets of the workbook 
For Each sht In ThisWorkbook.Worksheets 
iCntr = iCntr + 1 
'Applying the colors to Sheet tabs 
sht.Tab.ColorIndex = iCntr 
Next 
End Sub 

助けがあれば助かります。タイ！

Answer 1

はこれを試してみてください：

Sub sbColorAllSheetTab() 

    Dim iCntr, sht, arrColors, numColors 

    arrColors = Array(3, 5, 6, 12) '<< array of color indexes 

    iCntr = 0 
    numColors = UBound(arrColors) + 1 '<< how many colors? 

    For Each sht In ThisWorkbook.Worksheets 
     sht.Tab.ColorIndex = arrColors((iCntr Mod 4)) '<< use Mod to cycle color 
     iCntr = iCntr + 1 
    Next 

End Sub 

Answer 2

は、私はあなたにこの程度のことを何をすべきか知ってみましょう

Sub sbColorAllSheetTab() 
    Dim iCntr As Long, sht As Worksheet, arr 
    arr = Array(3, 5, 6, 12, ...) ' any sequence 

    For Each sht In ThisWorkbook.Worksheets 
     sht.Tab.ColorIndex = arr(iCntr) 
     iCntr = (iCntr + 1) Mod (UBound(arr) + 1) 
    Next 
End Sub 

Answer 3

それを介してアレイとインデックスを使用してください。

Sub sbColorAllSheetTab() 
Dim shtMod As Byte 
'looping throgh the all the sheets of the workbook 
For Each sht In ThisWorkbook.Worksheets 
    shtMod = sht.Index Mod 4 
    Select Case shtMod 
     Case 1 
      sht.Tab.ColorIndex = 3 
     Case 2 
      sht.Tab.ColorIndex = 5 
     Case 3 
      sht.Tab.ColorIndex = 6 
     Case 0 
      sht.Tab.ColorIndex = 12 
    End Select 
    Next 
End Sub