Appleがボリュームマウントをロードし、アプリケーションを起動し、macがサスペンド状態から外れると再起動します。

Question

私のMacでネットワーク上のSMB共有に接続する際に問題が発生し、その直後にアプリケーションをロードしています。

Macはいつものようにログインの上にマウントし、そしてまた、ログインの上にアプリケーション（XBMC）を実行するボリュームを設定することで、ちょうどオンになるとほとんどの部分については、すべてが動作します。それはネットワーク上の場所が使用できないと考えているよう

は時折しかし、私は、トラブルシューティングの大規模な量の後に突き止めることができた理由もなく、ボリュームの自動マウントは、いくつかの回は失敗します。その結果、Macを再起動しない限り、Macはボリュームマウントを作成できません。その後、再び動作します。

は、今私は、ボリュームが3回をマウントして、XBMCを読み込む作成しようとしたAppleScriptをしたいです。 3回試行してもボリュームをマウントできない場合は、強制的にMacを再起動してください。これにより、再起動後にスクリプトが最初から実行されるようになります。

これをAppleScriptでどのように達成できますか？

第二の問題：

私は私のMacは非アクティブの1時間後に停止する行くように設定されています。唯一の問題は、Macがしばらくの間中断された場合、目を覚ますとXBMCが遠隔格納されたコンテンツをいつかロードすることができないということです。

だから、MacはMacが再起動を行わせること、中断されてから再開すると、スクリプトの実行を有することが可能ですか？私の記事の全文を読んでいる人には

おかげで、私はそれは暴言のビットです実現しています。

よろしくお願いいたします。

Answer 1

あなたの最初の質問にこれを試してください。あなたの「サスペンド」の質問に関しては、私は答えをわかりません。しかし、私はlaunchdを調べます。 Macが再開したときに実行されるlaunchd plistファイルを書き込むことができます。また、launchd plistは、コマンドラインツールosascriptを使用してapplescriptを実行するだけです。このため

set remoteDiskName to "Disk Name" 
set remoteIPAddress to "192.168.1.xxx" 
set user_name to "userName" 
set pass_word to "password" 

repeat 3 times 
    set success to mountSMB(remoteDiskName, remoteIPAddress, user_name, pass_word) 
    if success then exit repeat 
    delay 1 
end repeat 

if success then 
    -- load XBMC 
else 
    tell application "Finder" to restart 
end if 

on mountSMB(remoteDiskName, remoteIPAddress, user_name, pass_word) 
    if remoteDiskName is in (do shell script "/bin/ls /Volumes") then 
     return true 
    else 
     set theAddress to quoted form of ("smb://" & user_name & ":" & pass_word & "@" & remoteIPAddress & "/" & remoteDiskName) 
     set mountpoint to quoted form of ("/Volumes/" & remoteDiskName) 
     try 
      do shell script "/bin/mkdir " & mountpoint & "; /sbin/mount_smbfs " & theAddress & space & mountpoint 
      return true 
     on error 
      try 
       do shell script "/bin/rm -r " & mountpoint 
      end try 
      return false 
     end try 
    end if 
end mountSMB