名前付き範囲の検索と置換

Question

何らかの理由で、YTDとYTGの値を "、9"、 "、12"に変更しても、仕事。ここに私が持っているものがあります。

Sub Rename() 
    Dim YTG As String 
    Dim YTD As String 
    Dim Shiftold As String 
    Dim Shitnew As String 

i = 1 

YTG = "<>YTG" 
YTD = "YTD" 
Shiftold = "0,0,1" 
ShiftNew = "0,12,1" 


For Each Name In ActiveWorkbook.Names 
    If InStr(1, Names(i).RefersTo, YTG) > 0 Then 
    Names(i).RefersTo = Replace(Names(i).RefersTo, YTG, YTD) 
    End If 

    If InStr(1, Names(i).RefersTo, Shiftold) > 0 Then 
    Names(i).RefersTo = Replace(Names(i).RefersTo, Shiftold, ShiftNew) 
    End If 

    i = i + 1 
Next Name 
End Sub 

マクロがもう機能しない理由についてのご意見はありますか？

Answer 1

変数宣言を強制的に使用することを強くお勧めします。これにより、タイプミスや宣言が欠けています。

Renameは、一般的な方法などと重複するため、マクロ名の恐ろしい選択です（Nameは悪い選択です）。この場合、実際に何が影響を受けるかはほとんど分かりません。

コメントに見られるように、実際にはFor Eachループ変数を使用していませんでした。これはかなり無意味ですが、実際にはコレクションの要素にアクセスするためのより良い方法になります。

以下は改善点です。コメントは私がそれをどのように変更したかについて話していることに注意してください。実際には、これらを使用するのではなく、実際の目的を説明するコメントを追加してください。

Sub UpdateNamedRanges() ' specific macro title 

Dim YTG As String 
Dim YTD As String 
Dim ShiftOld As String 
Dim ShiftNew As String ' corrected 
Dim AName As Name 'declared 

YTG = "<>YTG" 
YTD = "YTD" 
ShiftOld = "0,0,1" 
ShiftNew = "0,12,1" 

For Each AName In ActiveWorkbook.Names 
    ' use loop variable 
    If InStr(1, AName.RefersTo, YTG) > 0 Then 
     AName.RefersTo = Replace(AName.RefersTo, YTG, YTD) 
    End If 

    If InStr(1, AName.RefersTo, ShiftOld) > 0 Then 
     AName.RefersTo = Replace(AName.RefersTo, ShiftOld, ShiftNew) 
    End If 
Next AName 

End Sub