フォーマット名を関数の入力として使用します。fcmp

Question

2つの異なるフォーマットが定義されています。フォーマットされた

proc format; 
value fmtA 
1 = 3 
2 = 5 
; 
value fmtB 
1 = 2 
2 = 4 
; 
run; 

機能myfun戻り、私はこれは少しよりダイナミックにしたい値

proc fcmp outlib=WORK.pac.funcs; 
    function myfun(n); 
     val = put(n,fmta.); 
     return (val); 
    endsub; 
run; 

- valは関数の入力に基づいて行われます。

EDIT

proc fcmp outlib=WORK.pac.funcs; 
    function myfun(n,myfmt $); 
     if myfmt = 'fmtA' then val = put(n,fmtA.); 
     else if myfmt = 'fmtB' then val = put(n,fmtB.); 
     else val = n; 
     return (val); 
    endsub; 
run; 

data test; 
    n = 2; 
    myfmt = 'fmtA'; 
    output; 
    myfmt = 'fmtB'; 
    output; 
    myfmt = 'fmtC'; 
    output; 
run; 

data test2; 
    set test; 
    /* try to do sth like this */ 
    value = myfun(n,myfmt); 
run; 

このソリューションは、動作します。しかし、それは私が非常に多くの異なるフォーマットを持っているときにチェックの長いリストが必要です。そして、私が入力testデータセットの形式名を見る前に、それは不可能です。

Answer 1

PUTN（）関数を使用してください。

proc format; 
value fmtA 1 = '3' 2 = '5' ; 
value fmtB 1 = '2' 2 = '4' ; 
value fmtc 1 = '1' 2 = '3' ; 
run; 
data test; 
    do myfmt = 'fmtA.','fmtB.','fmtC.'; 
    do n= 1,2; 
    str = putn(n,myfmt); 
    value = input(str,32.); 
    output; 
    end; 
    end; 
run;