X個の行ごとに静的テキストをセルに入力する

Question

X個のレコードごとに空白の行を埋め込むコードがあります。私がしたいのは、いくつかのコードを用意して、それらの空の行のセルに静的なテキストを挿入することです。ここで私は空白の行を追加するために持っているものです...すべての鉱山ではなく、私はインターネットからそれを摘発しました。私が必要とするのは、作成中の空白行に静的テキストを埋め込むことです。その後、パディングを続け、50レコードごとに追加します。ありがとう！

********** 
Sub InsertRowEveryXrows() 

    Dim rw As Long 
    Dim lr As Long 
    Dim cnt As Long 
    lr = Range("A" & Rows.Count).End(xlUp).Row 
    rw = 2 
    cnt = 1 
    Do 
    If cnt = 50 Then 
     Rows(rw).Insert Shift:=xlDown 
     cnt = 1 

    Else 
     cnt = cnt + 1 
    End If 
    rw = rw + 1 
    Loop While rw <> lr 
End Sub 
***************** 

Answer 1

あなたはそれがこのように、（それが1だ列を想定）51にそれを作るとあなたの静的なテキストを追加CNT時に尋ねるだしなければならない唯一の事：

Sub InsertRowEveryXrows() 

    Dim rw As Long 
    Dim lr As Long 
    Dim cnt As Long 
    lr = Range("A" & Rows.Count).End(xlUp).Row 
    rw = 2 
    cnt = 1 
    Do 
    If cnt = 50 Then 
     Rows(rw).Insert Shift:=xlDown 
     cnt = 1 
    Else 
     if cnt = 51 then 
      cells(rw,1) = "your static text" 
     else 
     cnt = cnt + 1 
     End If 
    End If 
    rw = rw + 1 
    Loop While rw <> lr 

End Sub 

それはどのようになる教えてください、それが役に立てば幸い ！

Answer 2

私は何が起こっていたかを示すためにコードにコメントを追加しましたが、これは私のために働きました。

Public Sub Sample() 
Dim WkSht As Worksheet 
Dim LngLR As Long 'Last Row 
Dim LngCR As Long 'Current Row 

'Connect to the worksheet 
Set WkSht = ThisWorkbook.Worksheets("Sheet1") 

    'Get the last row so we know when to stop 
    LngLR = WkSht.Range("A" & WkSht.Rows.Count).End(xlUp).Row 

    LngCR = 51 '51 to account for the first row being a header 

    'Keep adding the 50th row until when would end up past the last row 
    Do Until LngCR > LngLR 

     'Add the new row 
     WkSht.Rows(LngCR).Insert Shift:=xlDown 

     'Populate it 
     WkSht.Range("A" & LngCR) = "Your static text" 

     'Increase the last row as it will now be one more 
     LngLR = LngLR + 1 

     'Got to the next 50th 
     LngCR = LngCR + 50 
    Loop 

Set WkSht = Nothing 

End Sub 

• これは良い習慣であるように私は、変数としてワークシートに接続され、あなたのやっは今のところ正常に動作するものが、それは読むために混乱することができ、コードが大きくあいまいさを取得した場合、原因の物事はあなたが起こるために作ります期待していませんでした。
• 1つではなく50ずつ増やしていますが、技術的には50倍速くなりましたが、今日のコンピュータではすべてがぼやけています:)
• 最後の行が毎回あなたは行を追加しました。