vbaコードを使用して1枚のシートから複数のシートに条件付きコピーする

Question

こんにちは、1枚のシートから複数枚のシートに条件付きでデータをコピーするコードがあります。このコードは、宛先シートにデータをコピーする前に、宛先シートの選択範囲内のすべてのデータを削除します。私にとってはこの部分はうまくいきましたが、データを削除した後、コードは宛先シートにデータを貼り付けていません。また、空でない文字列のコードを "、"として設定しています。これは動作しないかどうかわかりません。このコードはエラーを出さないので、これを並べ替えることはできません。コードは次のとおりです： -

Option Explicit 
Sub Main() 
Dim Rng As Range 
Dim Cl As Range 
Dim str1 As String 
Dim str2 As String 
Dim RowEmpCrnt As Long 
Dim RowUpdCrnt As Long 
Dim WshtEmp As Worksheet 

Set WshtEmp = Sheets("Employee Data") 
Set Rng = WshtEmp.UsedRange 'the range to search ie the used range 
str1 = "" 'string1 to look for should be empty 
str2 = "Working" 'string2 to look for should be empty 
Sheets("Updated").Range("B4:AV20000").Value = "" 
RowUpdCrnt = 1 
For Each Cl In Rng.Columns("AK").Rows 
If Cl.Text = str1 Then 
RowEmpCrnt = Cl.Row 
If WshtEmp.Cells(RowEmpCrnt, "AV").Value = str2 Then 
' In my test data, the "Working"s are in column AV and blank cells are in column AK. This For-Each only selects column AV. 
' If both column "AK" and column "AV" contain the correct value copy it to next empty row on sheet Updated 
Cl.Range("B4:AV4").Copy Sheets("Updated").Range("B3").Cells(RowUpdCrnt, 1) 
With WshtEmp.Rows(RowEmpCrnt) 
Set Rng = WshtEmp.Range(.Cells(2), .Cells(100))  ' range A:Z 
End With 
Rng.Copy Destination:=Sheets("Updated").Range("B3").Cells(RowUpdCrnt, 1) 
RowUpdCrnt = RowUpdCrnt + 1 
End If 
End If 
Next Cl 


Set Rng = Sheets("Employee Data").UsedRange 'the range to search ie the used range 
str1 = "," 'string1 to look for should be non empty 
str2 = "Transferred" 'string2 to look for 
Sheets("Transferred").Range("B4:AV20000").Value = "" 
RowUpdCrnt = 1 
For Each Cl In Rng.Columns("AK").Rows 
If Cl.Text = str1 Then 
RowEmpCrnt = Cl.Row 
If WshtEmp.Cells(RowEmpCrnt, "AV").Value = str2 Then 
' In my test data, the "Transferred"s are in column AV and blank cells are in column AK. This For-Each only selects column AV. 
' If both column "AK" and column "AV" contain the correct value copy it to next empty row on sheet Transferred 
Cl.Range("B4:AV4").Copy Sheets("Transferred").Range("B3").Cells(RowUpdCrnt, 1) 
With WshtEmp.Rows(RowEmpCrnt) 
Set Rng = WshtEmp.Range(.Cells(2), .Cells(100))  ' range A:Z 
End With 
Rng.Copy Destination:=Sheets("Transferred").Range("B3").Cells(RowUpdCrnt, 1) 
RowUpdCrnt = RowUpdCrnt + 1 
End If 
End If 
Next Cl 


Set Rng = Sheets("Employee Data").UsedRange 'the range to search ie the used range 
str1 = "Executive" 'string1 to look for 
str2 = "Working" 'string2 to look for 
Sheets("Executive").Range("B4:AV20000").Value = "" 
RowUpdCrnt = 1 
For Each Cl In Rng.Columns("F").Rows 
If Cl.Text = str1 Then 
RowEmpCrnt = Cl.Row 
If WshtEmp.Cells(RowEmpCrnt, "AV").Value = str2 Then 
' In my test data, the "Executive"s are in column F and "Working"s are in column AV. This For-Each only selects column AV. 
' If both column "F" and column "AV" contain the correct value copy it to next empty row on sheet Executive 
Cl.Range("B4:AV4").Copy Sheets("Executive").Range("B3").Cells(RowUpdCrnt, 1) 
With WshtEmp.Rows(RowEmpCrnt) 
Set Rng = WshtEmp.Range(.Cells(2), .Cells(100))  ' range A:Z 
End With 
Rng.Copy Destination:=Sheets("Executive").Range("B3").Cells(RowUpdCrnt, 1) 
RowUpdCrnt = RowUpdCrnt + 1 
End If 
End If 
Next Cl 

Set Rng = Sheets("Employee Data").UsedRange 'the range to search ie the used range 
str1 = "Supervisior" 'string1 to look for 
str2 = "Working" 'string2 to look for 
Sheets("Supervisior").Range("B4:AV20000").Value = "" 
RowUpdCrnt = 1 
For Each Cl In Rng.Columns("F").Rows 
If Cl.Text = str1 Then 
RowEmpCrnt = Cl.Row 
If WshtEmp.Cells(RowEmpCrnt, "AV").Value = str2 Then 
' In my test data, the "Supervisior"s are in column F and "Working"s are in column AV. This For-Each only selects column AV. 
' If both column "F" and column "AV" contain the correct value copy it to next empty row on sheet Supervisior 
Cl.Range("B4:AV4").Copy Sheets("Supervisior").Range("B3").Cells(RowUpdCrnt, 1) 
With WshtEmp.Rows(RowEmpCrnt) 
Set Rng = WshtEmp.Range(.Cells(2), .Cells(100))  ' range A:Z 
End With 
Rng.Copy Destination:=Sheets("Supervisior").Range("B3").Cells(RowUpdCrnt, 1) 
RowUpdCrnt = RowUpdCrnt + 1 
End If 
End If 
Next Cl 


Set Rng = Sheets("Employee Data").UsedRange 'the range to search ie the used range 
str1 = "Workmen" 'string1 to look for 
str2 = "Working" 'string2 to look for 
Sheets("Workmen").Range("B4:AV20000").Value = "" 
RowUpdCrnt = 1 
For Each Cl In Rng.Columns("F").Rows 
If Cl.Text = str1 Then 
RowEmpCrnt = Cl.Row 
If WshtEmp.Cells(RowEmpCrnt, "AV").Value = str2 Then 
' In my test data, the "Workmen"s are in column F and "Working"s are in column AV. This For-Each only selects column AV. 
' If both column "F" and column "AV" contain the correct value copy it to next empty row on sheet Supervisior 
Cl.Range("B4:AV4").Copy Sheets("Workmen").Range("B3").Cells(RowUpdCrnt, 1) 
With WshtEmp.Rows(RowEmpCrnt) 
Set Rng = WshtEmp.Range(.Cells(2), .Cells(100))  ' range A:Z 
End With 
Rng.Copy Destination:=Sheets("Workmen").Range("B3").Cells(RowUpdCrnt, 1) 
RowUpdCrnt = RowUpdCrnt + 1 
End If 
End If 
Next Cl 

End Sub 

Answer 1

私はコードの各行を読みませんでしたが、あなたの問題の説明に基づいてこれがうまくいくと思います。

すべての一意の値 他の例と例のための新しいブックを作成しますが、より多くの例について

をワークブックと、以下のコードで例のワークブックに行く：新しいシートに列に同じ値を持つ コピーレコードrange.Theのワークブックの最初の列内のすべてのユニークな値のための新しいワークブックが新たに作成されたに名前でユニークな値で保存されますまたはワークブック

The range for the code example below looks like this 
Column A : Header in A1 = Country, A2:A? = Country names 
Column B : Header in B1 = Name, B2:B? = Names 
Column C : Header in C1 = Gender, C2:C? = F or M 
Column D : Header in D1 = Birthday, D2:D? = Dates 

この例では、あなたのために新しいフォルダを作成します。フォルダ。新しく作成されたワークブックへのハイパーリンクを含むワークシートを「RDBLogSheet」というワークブックに追加することで、ワークブックを簡単に開くことができます。マクロを実行するたびに、このワークシートが最初に削除されるので、情報は最新です。

チェックマクロ

1を実行する前に、マクロでこれらの行の情報が正しい場合：ActiveSheetに設定されたフィルタ範囲：A1は、あなたのフィルタの範囲の左上のセルと最初の列のヘッダーです、Dはフィルター範囲の最後の列です。 ワークシート（ "Sheet1"）。範囲（ "A1：D" & LastRow（Worksheets（ "Sheet1"））） シートがアクティブである必要はありません。これを使用すると、マクロを実行します。 Set My_Range = Range（ "A1：D" & LastRow（ActiveSheet））

2：フィルタのフィールドを設定します。この例は、範囲内の最初の列のフィルターです（必要に応じてフィールドを変更します）。この場合、範囲は、2 =列B、...ので、フィールド1は列Aで開始 FieldNum = 1

3：重要：このマクロ呼び出しLASTROW という関数は、この関数を見つけますマクロの下に、標準モジュールのマクロと共にこの関数をコピーしてください。

Sub Copy_To_Workbooks() 
'Note: This macro use the function LastRow 
    Dim My_Range As Range 
    Dim FieldNum As Long 
    Dim FileExtStr As String 
    Dim FileFormatNum As Long 
    Dim CalcMode As Long 
    Dim ViewMode As Long 
    Dim ws2 As Worksheet 
    Dim MyPath As String 
    Dim foldername As String 
    Dim Lrow As Long 
    Dim cell As Range 
    Dim CCount As Long 
    Dim WSNew As Worksheet 
    Dim ErrNum As Long 

    'Set filter range on ActiveSheet: A1 is the top left cell of your filter range 
    'and the header of the first column, D is the last column in the filter range. 
    'You can also add the sheet name to the code like this : 
    'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1"))) 
    'No need that the sheet is active then when you run the macro when you use this. 
    Set My_Range = Range("A1:D" & LastRow(ActiveSheet)) 
    My_Range.Parent.Select 

    If ActiveWorkbook.ProtectStructure = True Or _ 
     My_Range.Parent.ProtectContents = True Then 
     MsgBox "Sorry, not working when the workbook or worksheet is protected", _ 
       vbOKOnly, "Copy to new workbook" 
     Exit Sub 
    End If 

    'This example filters on the first column in the range(change the field if needed) 
    'In this case the range starts in A so Field:=1 is column A, 2 = column B, ...... 
    FieldNum = 1 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    'Set the file extension/format 
    If Val(Application.Version) < 12 Then 
     'You use Excel 97-2003 
     FileExtStr = ".xls": FileFormatNum = -4143 
    Else 
     'You use Excel 2007-2013 
     If ActiveWorkbook.FileFormat = 56 Then 
      FileExtStr = ".xls": FileFormatNum = 56 
     Else 
      FileExtStr = ".xlsx": FileFormatNum = 51 
     End If 
    End If 

    'Change ScreenUpdating, Calculation, EnableEvents, .... 
    With Application 
     CalcMode = .Calculation 
     .Calculation = xlCalculationManual 
     .ScreenUpdating = False 
     .EnableEvents = False 
    End With 
    ViewMode = ActiveWindow.View 
    ActiveWindow.View = xlNormalView 
    ActiveSheet.DisplayPageBreaks = False 

    'Delete the sheet RDBLogSheet if it exists 
    On Error Resume Next 
    Application.DisplayAlerts = False 
    Sheets("RDBLogSheet").Delete 
    Application.DisplayAlerts = True 
    On Error GoTo 0 

    ' Add worksheet to copy/Paste the unique list 
    Set ws2 = Worksheets.Add(After:=Sheets(Sheets.Count)) 
    ws2.Name = "RDBLogSheet" 

    'Fill in the path\folder where you want the new folder with the files 
    'you can use also this "C:\Users\Ron\test" 
    MyPath = Application.DefaultFilePath 

    'Add a slash at the end if the user forget it 
    If Right(MyPath, 1) <> "\" Then 
     MyPath = MyPath & "\" 
    End If 

    'Create folder for the new files 
    foldername = MyPath & Format(Now, "yyyy-mm-dd hh-mm-ss") & "\" 
    MkDir foldername 

    With ws2 
     'first we copy the Unique data from the filter field to ws2 
     My_Range.Columns(FieldNum).AdvancedFilter _ 
       Action:=xlFilterCopy, _ 
       CopyToRange:=.Range("A3"), Unique:=True 

     'loop through the unique list in ws2 and filter/copy to a new sheet 
     Lrow = .Cells(Rows.Count, "A").End(xlUp).Row 
     For Each cell In .Range("A4:A" & Lrow) 

      'Filter the range 
      My_Range.AutoFilter Field:=FieldNum, Criteria1:="=" & _ 
      Replace(Replace(Replace(cell.Value, "~", "~~"), "*", "~*"), "?", "~?") 

      'Check if there are no more then 8192 areas(limit of areas) 
      CCount = 0 
      On Error Resume Next 
      CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible) _ 
        .Areas(1).Cells.Count 
      On Error GoTo 0 
      If CCount = 0 Then 
       MsgBox "There are more than 8192 areas for the value : " & cell.Value _ 
        & vbNewLine & "It is not possible to copy the visible data." _ 
        & vbNewLine & "Tip: Sort your data before you use this macro.", _ 
         vbOKOnly, "Split in worksheets" 
      Else 
       'Add new workbook with one sheet 
       Set WSNew = Workbooks.Add(xlWBATWorksheet).Worksheets(1) 

       'Copy/paste the visible data to the new workbook 
       My_Range.SpecialCells(xlCellTypeVisible).Copy 
       With WSNew.Range("A1") 
        ' Paste:=8 will copy the columnwidth in Excel 2000 and higher 
        ' Remove this line if you use Excel 97 
        .PasteSpecial Paste:=8 
        .PasteSpecial xlPasteValues 
        .PasteSpecial xlPasteFormats 
        Application.CutCopyMode = False 
        .Select 
       End With 

       'Save the file in the new folder and close it 
       On Error Resume Next 
       WSNew.Parent.SaveAs foldername & _ 
            cell.Value & FileExtStr, FileFormatNum 
       If Err.Number > 0 Then 
        Err.Clear 
        ErrNum = ErrNum + 1 

        WSNew.Parent.SaveAs foldername & _ 
        "Error_" & Format(ErrNum, "0000") & FileExtStr, FileFormatNum 

        .Cells(cell.Row, "B").Formula = "=Hyperlink(""" & foldername & _ 
         "Error_" & Format(ErrNum, "0000") & FileExtStr & """)" 

        .Cells(cell.Row, "A").Interior.Color = vbRed 
       Else 
        .Cells(cell.Row, "B").Formula = _ 
        "=Hyperlink(""" & foldername & cell.Value & FileExtStr & """)" 
       End If 

       WSNew.Parent.Close False 
       On Error GoTo 0 
      End If 

      'Show all the data in the range 
      My_Range.AutoFilter Field:=FieldNum 

     Next cell 
     .Cells(1, "A").Value = "Red cell: can't use the Unique name as file name" 
     .Cells(1, "B").Value = "Created Files (Click on the link to open a file)" 
     .Cells(3, "A").Value = "Unique Values" 
     .Cells(3, "B").Value = "Full Path and File name" 
     .Cells(3, "A").Font.Bold = True 
     .Cells(3, "B").Font.Bold = True 
     .Columns("A:B").AutoFit 

    End With 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    If ErrNum > 0 Then 
     MsgBox "Rename every WorkSheet name that start with ""Error_"" manually" _ 
      & vbNewLine & "There are characters in the name that are not allowed" _ 
      & vbNewLine & "in a sheet name or the worksheet already exist." 
    End If 

    'Restore ScreenUpdating, Calculation, EnableEvents, .... 
    My_Range.Parent.Select 
    ActiveWindow.View = ViewMode 
    ws2.Select 
    With Application 
     .ScreenUpdating = True 
     .EnableEvents = True 
     .Calculation = CalcMode 
    End With 

End Sub 


Function LastRow(sh As Worksheet) 
    On Error Resume Next 
    LastRow = sh.Cells.Find(What:="*", _ 
          After:=sh.Range("A1"), _ 
          Lookat:=xlPart, _ 
          LookIn:=xlValues, _ 
          SearchOrder:=xlByRows, _ 
          SearchDirection:=xlPrevious, _ 
          MatchCase:=False).Row 
    On Error GoTo 0 
End Function