バッチが存在する場合は常にfalseを返します

Question

これまでにバッチスクリプトを作成したことはありませんでしたが、学習プロセスに入りましたが...

ネットワークドライブを自動的にマップするスクリプトを作成しようとしています。フォルダが存在するかどうかを判断するためにif existステートメントを含めました。しかし、たとえそれがあってもフォルダが存在しないかのように、if statementをそのまま終了します。コマンドを個別に実行すると、そのコマンドは機能します（たとえば、if exist \\domain\folder\desired_folder (echo true) else (echo false)は真となります）。それはif statementsを通過させ、else statement

ここで私は、それが最初if statementに入ると、ドライブをマッピングする必要があるとの問題を抱えている私のコードがあるにまっすぐに行くように思える...任意の助けいただければ幸いです。

REM define %A and %B 
SET totalname="net user %USERNAME% /domain | FIND /i "Full Name"" 

FOR /f "tokens=3-4 delims=, " %%A IN ('%totalname%') DO SET drivename=%%A_%%B 


REM check if I drive folder exists 
if exist "\\domain\folder\%%A_%%B" (
REM delete current I drive 
REM map I drive 
net use i: /delete 
net use i: \\domain\folder\%drivename% /P:YES 
) else if exist \\domain\folder\%USERNAME% (
    net use i: /delete 
    net use i: \\domain\folder\%USERNAME% /P:YES 
) else (
    echo ERROR: File Not Found 
    echo ERROR: Unable to map I drive 

    REM for debugging purposes: %username% & %drivename% echo the desired result 
    echo username %USERNAME% 
    echo a_b %drivename% 
    pause 
    exit 
) 

Answer 1

%%Aと%%Bのみfor /Fループのコンテキストで存在する、ループのよう%%Aと%%B外側は文字通り%Aと%Bに拡張しようとしています。あなたは、変数drivenameにループ内%%A_%%Bを割り当てるので、後からではなく%%A_%%B%drivename%を使用しています

また、私が引用されset構文をお勧めします、そして、すべてのパスの前後に引用符を配置します。

ので：

for /F "tokens=3-4 delims=, " %%A in (' 
    net user %USERNAME% /domain ^| find /I "Full Name" 
') do set "drivename=%%A_%%B" 
rem // more code... 
if exist "\\domain\folder\%drivename%" (
    rem // more code... 
) else if exist "\\domain\folder\%USERNAME%" (
    rem // more code... 
) else (
    rem // more code... 
)