環境に応じた特定のGebテストの実行

Question

私はGrailsプロジェクト内で実行している一連のSpecテストを持っています。

私がローカルにいるときには特定のセットを実行し、プリプロード環境を実行するときには別のセットを実行する必要があります。 私の現在の設定は、両方の環境に対して同時にすべての仕様を実行しています。これは避けたいものです。

私は私のGebConfigに設定されていることを、複数の環境を持っている：

environments { 
    local { 
     baseUrl = "http://localhost:8090/myApp/login/auth" 
    } 

    pre-prod { 
     baseUrl = "https://preprod/myApp/login/auth" 
    } 

} 

Answer 1

あなたはスポックの設定ファイルを使用することができます。

テストの2種類の注釈を作成 - @Localと@PreProdを、Groovyで例えば：

import java.lang.annotation 

@Retention(RetentionPolicy.RUNTIME) 
@Target([ElementType.TYPE, ElementType.METHOD]) 
@Inherited 
public @interface Local {} 

次のステップは、例えば、それに応じてスペックに注釈を付けることである。

@Local 
class SpecificationThatRunsLocally extends GebSpec { ... } 

次に作成次のコンテンツを含むGebConfig.groovyファイルの隣にSpockConfig.groovyファイルがあります。

def gebEnv = System.getProperty("geb.env") 
if (gebEnv) { 
    switch(gebEnv) { 
     case 'local': 
      runner { include Local } 
      break 
     case 'pre-prod': 
      runner { include PreProd } 
      break 
    } 
} 

編集：Grailsが独自のテストランナーを使用しているようです。つまり、Grailsから仕様を実行するときにSpockConfig.groovyが考慮されていないことを意味します。 Grailsの下で動作する必要がある場合は、@ IgnoreIf/@ Requireが組み込みSpock拡張アノテーションを使用する必要があります。

まず、特定の仕様を有効にする必要がある場合のロジックを使用してClosureクラスを作成します。論理を拡張注釈のクロージャ引数として直接入れることもできますが、たくさんの仕様に注釈を付ける場合は、その場所のコードをコピーするのは面倒です。その後、

class Local extends Closure<Boolean> { 
    public Local() { super(null) } 
    Boolean doCall() { 
     System.properties['geb.env'] == 'local' 
    } 
} 

class PreProd extends Closure<Boolean> { 
    public PreProd() { super(null) } 
    Boolean doCall() { 
     System.properties['geb.env'] == 'pre-prod' 
    } 
} 

そして、あなたのスペックに注釈を付ける：

@Requires(Local) 
class SpecificationThatRunsLocally extends GebSpec { ... } 

@Requires(PreProd) 
class SpecificationThatRunsInPreProd extends GebSpec { ... }