これは良い方法です。ここの近くにヒットです:これは、すべての一等書記官を取り、そのプロパティと値
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>
select ?p ?o (count(distinct ?chancellor) as ?cs) where {
?chancellor wdt:P39 wd:Q4970706.
?chancellor ?p ?o .
}
group by ?p ?o
order by desc(?cs)
Link to query
。プロップ/ヴァルあたりのチャンセラー数を数えます。
注文すると、最も一般的なprop/valが上部に表示されます。
あなたが望むのは、すべての大統領にとって唯一の結果です。私たちは簡単に十分な1つのクエリ内の一等書記官の数を取得し、2つを固執することができます:
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>
select ?p ?o where {
{
# Find number of chancellors
select (count(?chancellor) as ?num_chancellors) where {
?chancellor wdt:P39 wd:Q4970706
}
}
{
# Find number of chancellors per predicate/value
select ?p ?o (count(distinct ?chancellor) as ?chancellor_count) where {
?chancellor wdt:P39 wd:Q4970706.
?chancellor ?p ?o .
}
group by ?p ?o
}
# Choose results all chancellors share
filter (?num_chancellors = ?chancellor_count)
}
Link to query。
私はこれがあなたが欲しいと思うと思います。それほどきれいではない、私は告白する。
すばらしい答え!アプローチ#1も面白いです! #2はまさに私が望んでいたものです。 – rinderwahn
クエリの結果が面白くないのは残念です。 - /最初の例でカウントするのではなくgroup_concatを使うと、有用なバリエーションであるpropanc/valを共有するチャンセラーが分かります。 – user205512