自動生成テキストボックス

Question

a イベントをクリックします。しかし、VBAでは、フォームをコントロールしやすくし、コーディングしていない人に使ってもらいたいので、コードを1つ1つ作成したくないので59 Subsをクリックします。はかなり醜いでしょう。私はVBAコードで別のサブを作成する必要がある以上を追加したい。

本当の質問は：さまざまな変数を持つテキスト/ボタンごとに自動コード（サブ）を実行する方法はありますか？

EG：

Text1_Click + Code -> Variable: 1 
Text2_Click + Code -> Variable: 2 
Text3_Click + Code -> Variable: 3 --> Text(?)_Click + Code -> Variable: ? 
Text4_Click + Code -> Variable: 4 
Text5_Click + Code -> Variable: 5 

Answer 1

は、VBA関数を作成し、各テキストボックスのクリック時プロパティのためにそれを使用する：あなたの例では=MyFunction()

、テキストボックスText1〜Text5という名前で、Variableをcテキストボックス名から番号を取得します。その番号はMid()で簡単に抽出できます。

Public Function MyFunction() 
    Dim strControl As String 
    Dim Variable As Variant 

    strControl = Application.Screen.ActiveControl.Name 
    Variable = Null 
    If strControl Like "Text*" Then 
     Variable = Val(Mid(strControl, 5)) 
    End If 
    Debug.Print strControl & "_Click -> Variable: " & Nz(Variable, "Null") 
End Function 

あなたは番号のコマンドボタンにそのアプローチを拡張したい場合は、これを含めます...

If strControl Like "Command*" Then 
     Variable = Val(Mid(strControl, 8)) 
    End If 

あなたは、プログラムでクリックでプロパティを割り当てるコントロールをループし、[ボタンでアイテムの配列]の各.OnClick = "=MyFunction()"

Answer 2

はい、あなたがコントロールを参照することができます！その後、CTLが私を参照します

n = 5 
Set ctl = Me("Text" & CStr(n)) 

Text5

しかし、WithEvents 0を見る：How to write generic code ...

Answer 3

フォームでは、ボタンを持っているし、次のコード

Option Explicit 

Public colCustomControls As Collection 

Private Sub Form_Open(Cancel As Integer) 

Dim ctl As Control 
Dim clsCustom As clsCustomButton 

    Set colCustomControls = New Collection 

    For Each ctl In Me.Controls 
     Set clsCustom = New clsCustomButton 
     clsCustom.INITIALISE ctl 
     colCustomControls.Add clsCustom 
    Next ctl 

End Sub 

何が起こっている

Option Explicit 

Private WithEvents cbCustom As CommandButton 

Public Sub INITIALISE(cb As CommandButton) 
    Set cbCustom = cb 
    cb.OnClick = "[Event Procedure]" 
End Sub 

Private Sub cbCustom_Click() 
    Select Case cbCustom.Name 
     Case "Command0": MsgBox "Button1 clicked" 
     Case "Command1": MsgBox "Button2 clicked" 
    End Select 
End Sub 

clsCustomButton

と呼ばれるクラスは、コレクションには、me.Controlsを模倣されていますコレクションをフォームに追加しますが、すべてのボタンをクラスにするので、クラス_clickイベントを使用しています。サブ呼び出しの場合は、初期化を変更してproc nameイベントを取得し、application.Runを使用してコードを呼び出すこともできます。

ようなので、

Option Explicit 

Private WithEvents cbCustom As CommandButton 
Private strProcCall As String 

Public Sub INITIALISE(cb As CommandButton, strProc As String) 
    Set cbCustom = cb 
    strProcCall = strProc 
    cb.OnClick = "[Event Procedure]" 
End Sub 

Private Sub cbCustom_Click() 
    Application.Run strProcCall 
End Sub 

と

Option Explicit 

Public colCustomControls As Collection 

Private Sub Form_Open(Cancel As Integer) 

Dim ctl As Control 
Dim clsCustom As clsCustomButton 

    Set colCustomControls = New Collection 

     Set clsCustom = New clsCustomButton 
     clsCustom.INITIALISE Me.Controls("Command0"), "MACRO_1" 
     colCustomControls.Add clsCustom 

     Set clsCustom = New clsCustomButton 
     clsCustom.INITIALISE Me.Controls("Command1"), "MACRO_2" 
     colCustomControls.Add clsCustom 

End Sub