Clojureでフックを行う方法

Question

私は、1つのクローズ・ネームスペース内のオブジェクトを作成して破棄し、別のネームスペースをコーディネイトする必要があるという状況があります。しかし、私は最初の名前空間がオブジェクトの破棄時に2番目の名前空間を明示的に呼び出さなければならないことは望ましくありません。

Javaでは、リスナーを使用できます。残念ながら、基礎となるJavaライブラリは、オブジェクトの破棄時にイベントを通知しません。私がEmacs-Lispにいたら、そのトリックを行うフックを使います。

今、私は確信していません。私はRobert Hookeのライブラリhttps://github.com/technomancy/robert-hookeを見つけました。しかし、これはelispの点では欠点に似ています - 私は関数を構成しています。ドキュメントの詳細：

"フックはあなたが制御しない機能を拡張することを意図しています;もしあなたが目的の機能を所有していれば、明らかにその動作を変更する良い方法があります。

悲しいことに、私はそれがとてもわかりません。

もう1つの可能性は、add-watchを使用することですが、これはアルファとしてマークされています。

別の明白な解決策がありませんか？

例を追加しました：

だから、まず名前空間....

(ns scratch-clj.first 
    (:require [scratch-clj.another])) 

(def listf (ref())) 

(defn add-object [] 
    (dosync 
    (ref-set listf (conj 
       @listf (Object.)))) 
    (println listf)) 


(defn remove-object [] 
    (scratch-clj.another/do-something-useful (first @listf)) 
    (dosync 
    (ref-set listf (rest @listf))) 
    (println listf)) 


(add-object) 
(remove-object) 

第二に、名前空間

(ns scratch-clj.another) 


(defn do-something-useful [object] 
    (println "object removed is:" object)) 

ここでの問題は、スクラッチclj.firstは別のものを必要とし、明示しなければならないことです削除イベントをプッシュします。これはちょっと大変ですが、 "もう一つの"名前空間があっても聞きたかったらうまくいきません。

私は最初の機能をフックすることを考えました。

Answer 1

は、このソリューションは、あなたの要件に適してますか？

スクラッチclj.first：

(ns scratch-clj.first) 

(def listf (atom [])) 
(def destroy-listeners (atom [])) 
(def add-listeners (atom [])) 

(defn add-destroy-listener [f] 
    (swap! destroy-listeners conj f)) 

(defn add-add-listener [f] 
    (swap! add-listeners conj f)) 

(defn add-object [] 
    (let [o (Object.)] 
    (doseq [f @add-listeners] (f o)) 
    (swap! listf conj o) 
    (println @listf))) 

(defn remove-object [] 
    (doseq [f @destroy-listeners] (f (first @listf))) 
    (swap! listf rest) 
    (println @listf)) 

いくつかのリスナー：

(ns scratch-clj.another 
    (:require [scratch-clj.first :as fst])) 

(defn do-something-useful-on-remove [object] 
    (println "object removed is:" object)) 

(defn do-something-useful-on-add [object] 
    (println "object added is:" object)) 

initはバインド：

(ns scratch-clj.testit 
    (require [scratch-clj.another :as another] 
      [scratch-clj.first :as fst])) 

(defn add-listeners [] 
    (fst/add-destroy-listener another/do-something-useful-on-remove) 
    (fst/add-add-listener another/do-something-useful-on-add)) 

(defn test-it [] 
    (add-listeners) 
    (fst/add-object) 
    (fst/remove-object)) 

テスト：

(test-it) 
=> object added is: #<Object java.lang.Object@c7aaef> 
    [#<Object java.lang.Object@c7aaef>] 
    object removed is: #<Object java.lang.Object@c7aaef> 
    () 

Answer 2

あなたが説明しているのはコールバックですね。以下のような

何か：

(defn make-object 
    [destructor-fn] 
    {:destructor destructor-fn :other-data "data"}) 

(defn destroy-object 
    [obj] 
    ((:destructor obj) obj)) 

; somewhere at the calling code... 

user> (defn my-callback [o] (pr [:destroying o])) 
#'user/my-callback 
user> (destroy-object (make-object my-callback)) 
[:destroying {:destructor #<user$my_callback user$my_callback@73b8cdd5>, :other-data "data"}] 
nil 
user> 

Answer 3

ここで、私の最終的なソリューションはmobytesの提案に従っています。もう少し仕事がありますが、 私は将来これが欲しいと思っています。すべてのヘルプ

;; hook system 
(defn make-hook [] 
    (atom [])) 

(defn add-hook [hook func] 
    (do 
    (when-not 
     (some #{func} @hook) 
     (swap! hook conj func)) 
    @hook)) 

(defn remove-hook [hook func] 
    (swap! hook 
     (partial 
      remove #{func}))) 

(defn clear-hook [hook] 
    (reset! hook [])) 

(defn run-hook 
    ([hook] 
     (doseq [func @hook] (func))) 
    ([hook & rest] 
     (doseq [func @hook] (apply func rest)))) 

(defn phils-hook [] 
    (println "Phils hook")) 

(defn phils-hook2 [] 
    (println "Phils hook2")) 


(def test-hook (make-hook)) 
(add-hook test-hook phils-hook) 
(add-hook test-hook phils-hook2) 
(run-hook test-hook) 
(remove-hook test-hook phils-hook) 
(run-hook test-hook)