VBScript経由で接続されたUSBデバイスのVID/PIDを取得

Question

接続されたUSBデバイスのVID/PIDを変数に保存できるVBScriptを探しています。では、これを行うためのVBScriptは何ですか？

Answer 1

WMIを使用して取得できますが、WMIに接続されたUSBデバイスの動的クラスはありません。
プラグインされたデバイスを取得するには、デバイスが接続されたUSBデバイスが必要です。
したがって、この例を考えてみます。

Option Explicit 
Dim oWMISrv, collDvcs, collUSBDvcs, iUSBDvc , iDvc, sDvcID, sPID, sVID 

Function ReplaceX(ByVal sValue, ByVal sPattern, ByVal sNValue) 
    Dim oReg : Set oReg = New RegExp 
    oReg.Pattern = sPattern 
    ReplaceX = oReg.Replace(sValue, sNValue) 
    Set oReg = Nothing 
End Function 

Set oWMISrv = GetObject("winmgmts:\\.\root\cimv2") 
Set collDvcs = oWMISrv.ExecQuery("Select * From Win32_USBControllerDevice") 

For Each iDvc In collDvcs 
    If InStr(iDvc.Dependent, "VID_") Then ' Except keychain drives 

     sDvcID = ReplaceX(iDvc.Dependent, ".*""(.*)""", "$1") 
     sPID = ReplaceX(sDvcID, ".*PID_([^\\]*).*", "$1") 
     sVID = ReplaceX(sDvcID, ".*VID_([^&]*).*", "$1") 

     Set collUSBDvcs = oWMISrv.ExecQuery _ 
     ("Select * From Win32_PnPEntity Where DeviceID = '" & sDvcID & "'") 
     For Each iUSBDvc in collUSBDvcs 
      Wscript.Echo "Name : "& iUSBDvc.Description 
      Wscript.Echo "VID : "& sVID 
      Wscript.Echo "PID : "& sPID 
      Wscript.Echo String(50, "-") 
     Next 
     Set collUSBDvcs = Nothing 

    End If 
Next 

Set collDvcs = Nothing 
Set oWMISrv = Nothing