AS3 Flash/Animate - ビジュアルグラフ - XMLまたはExcellのデータ

Question

私は長年Flashを設計プラットフォームとして使用してきました。私は約10年の初心者です。私は、印刷して手で塗りつぶすことを意図した様々なグラフをフラッシュで設計しました。しかし、通常は、データポイントとラインをFlashで直接描画してグラフを完成させます。私が実際にばかげた目的のためにフラッシュを使用しているという事実を無視して、データポイントシンボルをプロットし、XMLまたはExcelを使用してラインを連結することは可能ですか？

以前は外部画像ファイルを読み込むのにXMLを使用しました。

誰かが正しい方向に私を指すことができる場合は、簡単な修正を探していませんが、連絡を取ってください。

敬具、

リッチ

Answer 1

1. Excelを忘れてください。
2. XMLではそれほど難しいことではありません。ほんの一例。

var X:XML = 
    <root> 
     <point x="0" y="0" /> 
     <point x="100" y="100" /> 
     <point x="10" y="50" /> 
     <point x="200" y="10" /> 
     <point x="45" y="45" /> 
     <point x="35" y="100" /> 
    </root>; 

これはかなり基本的なことですが、それは、XMLノードのリストを参照し、その属性にアクセスする方法を示します。

drawZigzag(X); 

function drawZigzag(source:XML):void 
{ 
    // Get a list of points. 
    var aList:XMLList = source.child("point"); 

    // Get the starting point. 
    var aNode:XML = aList[0]; 
    var anX:Number = aNode.@x; 
    var anY:Number = aNode.@y; 

    // Start drawing. 
    graphics.lineStyle(0, 0x000000); 
    graphics.moveTo(anX, anY); 

    for (var i:int = 1; i < aList.length(); i++) 
    { 
     // Get the next coordinates. 
     aNode = aList[i]; 
     anX = aNode.@x; 
     anY = aNode.@y; 

     // Draw the line. 
     graphics.lineTo(anX, anY); 
    } 
} 

ここで、外部ファイルにしたい場合。これはエラー処理やものがなくてもかなり基本的ですが、すべてのことを正しく準備するとうまくいくはずです。

// I hope the following is self-explanatory. 
var xmlRequest:URLRequest = new URLRequest("your.xml"); 
var dataLoader:URLLoader = new URLLoader; 

// Loading is asynchronous so you need to listen for a relevant event. 
dataLoader.addEventListener(Event.COMPLETE, onFile); 
dataLoader.load(xmlRequest); 

function onFile(e:Event):void 
{ 
    // Of course, your file MUST be a valid XML. 
    var X:XML = new XML(dataLoader.data); 

    // The data are ready, you can call the drawing routine now. 
    drawZigzag(X); 
}