WordのActiveXを使用してデルファイに変換するdoc

Question

Word 2007またはWord 2010のPDFエクスポート機能を使用して、docまたはdocxをpdfに変換するコードを誰も書いていましたか？

Answer 1

私は以下の.vbsスクリプトを使用しています。あなたはDelphiのコードでそれを必要とする場合、変換するのは簡単だろう：

Const wdDoNotSaveChanges = 0 
Const wdRevisionsViewFinal = 0 
Const wdFormatPDF = 17 

Dim arguments 
Set arguments = WScript.Arguments 

Function DOC2PDF(sDocFile) 

    Dim fso ' As FileSystemObject 
    Dim wdo ' As Word.Application 
    Dim wdoc ' As Word.Document 
    Dim wdocs ' As Word.Documents 

    Set fso = CreateObject("Scripting.FileSystemObject") 
    sDocFile = fso.GetAbsolutePathName(sDocFile) 
    sPdfFile = fso.GetParentFolderName(sDocFile) + "\" + fso.GetBaseName(sDocFile) + ".pdf" 

    Set wdo = CreateObject("Word.Application") 
    Set wdocs = wdo.Documents 
    WScript.Echo "Opening: " + sDocFile 
    Set wdoc = wdocs.Open(sDocFile) 
    if fso.FileExists(sPdfFile) Then 
    fso.DeleteFile sPdfFile, True 
    End If 
    WScript.Echo "Converting to PDF: " + sPdfFile 
    Set wview = wdoc.ActiveWindow.View 
    wview.ShowRevisionsAndComments = False 
    wview.RevisionsView = wdRevisionsViewFinal 
    wdoc.SaveAs sPdfFile, wdFormatPDF 
    WScript.Echo "Conversion completed" 
    wdo.Quit wdDoNotSaveChanges 

    Set fso = Nothing 
    Set wdo = Nothing 

End Function 

If arguments.Count=1 Then 
    Call DOC2PDF(arguments.Unnamed.Item(0)) 
Else 
    WScript.Echo "Generates a PDF file from a Word document using Word PDF export." 
    WScript.Echo "" 
    WScript.Echo "Usage: doc2pdf.vbs <doc-file>" 
    WScript.Echo "" 
End If 

Answer 2

私がこれまで持っていないが、それは難しいことではありません。

• は、Word COMサーバーオブジェクトを作成します。 CreateOLEObject('Word.Application')
• オープンExportAsFixedFormat

を使用して Documents.Open

エクスポートPDFへのドキュメントを使用して文書を使用して

はここで基本骨格です：

uses 
    ComObj; 
const 
    wdExportFormatPDF = 17; 
var 
    Word, Doc: OleVariant; 
begin 
    Word := CreateOLEObject('Word.Application'); 
    Doc := Word.Documents.Open('C:\Document.docx'); 
    Doc.ExportAsFixedFormat('C:\Document.pdf', wdExportFormatPDF); 
end; 

注バージョンindepentとなるように、私は、OLEVariantといったようWordとDoc変数の両方を宣言しました（すなわち、このコードは、Word 2007または2010を使用している場合でも機能します）。必要に応じて、VCL Officeコンポーネントライブラリを使用することもできます。ドキュメント自体で多くの処理を行うなら、間違いなく速くなるでしょう。