頻繁に繰り返されるコードは、モジュール

Question

に変換私は、次のVBAコードを使用しています：

Private Sub btnStatistics_click() 
On Error GoTo Err_Handler 

Dim strPasswd As String 
strPasswd = InputBox("Please Enter Password", "Password Required") 

If strPasswd = Format(Now, "Hh") * 2 Then 
    DoCmd.Close acForm, "frmCustomer", acSaveYes 
    DoCmd.OpenForm "frmStatistics", acNormal, "", "", acEdit, acNormal 
    Exit Sub 
Else 
    MsgBox "Incorrect password!", vbOKOnly, "Password Info" 
End If 

Exit_This_Sub: 
    Exit Sub 
Err_Handler: 
    MsgBox "Error #: " & Err.Number & " " & Err.Description 
    Resume Exit_This_Sub 
End Sub 

私は別のことを行うためにさまざまな形で多くのボタンで、このVBAコードを使用しています。私は部分のstrPasswd = Format(Now, "Hh") * 2をモジュールに移動して、1か所で更新/変更できるようにしたいと思います。

Answer 1

それは、移動したいパスワードの唯一のテストであれば、Booleanを返しFunctionを作成します。

Function PasswordOK(strPwd As String) As Boolean 
    PasswordOK = strPwd = Format(Now, "Hh") * 2 
End Function 

、その後、あなたはとしてそれを使用することができます。

If PasswordOK(strPasswd) Then 
    DoCmd.Close acForm, "frmCustomer", acSaveYes 
    DoCmd.OpenForm "frmStatistics", acNormal, "", "", acEdit, acNormal 
    'Exit Sub '<-- this isn't needed, because the next 
      ' statement after this one is also Exit Sub 
Else 
    MsgBox "Incorrect password!", vbOKOnly, "Password Info" 
End If 

---

また、適切な場合は、さらにいくつかのパラメータを渡すことで、さらに多くのコードを共通ルーチンに移動できます。

Sub ChangeForm(oldForm As String, newForm As String) 
    Dim strPasswd As String 
    strPasswd = InputBox("Please Enter Password", "Password Required") 

    If strPasswd = Format(Now, "Hh") * 2 Then 
     DoCmd.Close acForm, oldForm, acSaveYes 
     DoCmd.OpenForm newForm, acNormal, "", "", acEdit, acNormal 
    Else 
     MsgBox "Incorrect password!", vbOKOnly, "Password Info" 
    End If 
End Sub 

と共通ルーチンに、単にパスワードの入力、およびそのテストを入れ、

Private Sub btnStatistics_click() 
    ChangeForm "frmCustomer", "frmStatistics" 
End Sub 

おそらくどこかの二つの間

---

それともとしてそれを使用します。

Function PasswordOK() As Boolean 
    Dim strPasswd As String 
    strPasswd = InputBox("Please Enter Password", "Password Required") 
    If strPasswd = Format(Now, "Hh") * 2 Then 
     PasswordOK = True 
    Else 
     MsgBox "Incorrect password!", vbOKOnly, "Password Info" 
     PasswordOK = False 
    End If 
End Function 

次のように使用してください。