Windowsバッチファイルを使用して1行を複数回実行するにはどうすればよいですか？

Question

私の要件は以下のとおりです。ここで

@echo off 
cls 
Set Sleep=0 
:start 
echo This is a loop 
xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
Set /A Sleep+=1 
echo DisplayingSleepvalue 
echo %Sleep% 
goto start 

私はいずれかがこの上で私を助けてもらえ30回 .... ためxx.exe yyyyy.dll /p:InputDataSource=Table:table.xmlにこの行を実行します。

おかげで、
Manasa

Answer 1

この方法を試してください： -

@echo off 
cls 
Set Sleep=0 
:start 
if %Sleep% == 30 (goto end) 
xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
echo This is a loop 
Set /A Sleep+=1 
echo %Sleep% 
goto start 
:end 
echo "am 30 now" 
pause 

Answer 2

はforコマンドを使用して試してみてください。

Answer 3

増分カウンタでGOTOループを使用できますが、FORループとLループがはるかに効率的です。

for /l %%N in (1 1 30) do someCommand 

研究、コマンドラインからHELP FORまたはFOR /?を入力して利用できるドキュメント。

ブロック全体を繰り返す場合は、ブロックをかっこで囲みます。スリープ変数の代わりにFOR %% N変数を使用できます。

@echo off 
cls 
for /l %%N in (1 1 30) do (
    echo This is a loop 
    xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
    echo DisplayingSleepvalue 
    echo %%N 
) 

例では必要ありませんが、ループ内で環境変数を操作する場合は、遅延拡張を使用する必要があります。通常の拡張%sleep%は、ループ全体が解析されたときに1回だけ展開されますが、実行時には各ループ反復ごとに!sleep!の値を展開する必要があります。遅延拡張を使用可能にする必要があります。

@echo off 
setlocal enableDelayedExpansion 
cls 
set sleep=0 
for /l %%N in (1 1 30) do (
    echo This is a loop 
    xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
    set /a sleep+=1 
    echo DisplayingSleepvalue 
    echo !sleep! 
) 

Answer 4

ホードはいくつかの数学を追加し、ループを得ました。

@echo off 
set execute counter=0 
:loop 
(Insert your command here) 
set /a executecounter=%executecounter%+1 
if "%executecounter%"=="30" goto done 
goto loop 
:done 
echo Complete! 
pause 

これにより、コマンドが実行されるたびにカウンタが増加し、30回実行するとプログラムは終了します。