クラスのスーパークラスを実行時にどのように決定できますか？

Question

Actionscript 3では、Classオブジェクトが指定されている場合、そのクラスが別のクラスから継承されているかどうかを判断する方法はありますか？私はクラスをインスタンス化してisキーワードでチェックしたくありません。

具体的には、私はこの機能を動作させるためにしようとしている：

public function validateClass(classObj:Class):EngineObject{ 
    if(classObj extends EngineObject){ 
     return new classObj(); 
    } else { 
     throw new Error("Given class is not a subclass of EngineObject!"); 
    } 
} 

編集：inはAS3

Answer 1

に予約されていることを忘れてはflash.utils.getQualifiedSuperclassName()とflash.utils.getQualifiedClassName()

を見てくださいあなたの機能はこのように見えるかもしれません。

import flash.utils.getQualifiedSuperclassName; 
import flash.utils.getQualifiedClassName; 

public function validateClass(cl:Class):EngineObject{ 
    if(getQualifiedSuperclassName(cl) == getQualifiedClassName(EngineObject)){ 
     return new cl(); 
    } else { 
     throw new Error("Given class is not a subclass of EngineObject!"); 
    } 
} 

しかし、これは単一の反復の深さでのみ機能します。

レベルがobjectになるまで、各繰り返しステップでこれを行うことができます。ここでは完全なアプローチです。

public function validateClass(cl:Class):EngineObject 
{ 
    if (getQualifiedSuperclassName(cl) == getQualifiedClassName(EngineObject)) 
    { 
     return new cl(); 
    } 

    var sup:Class = getDefinitionByName(getQualifiedSuperclassName(cl)) as Class; 
    if (sup == null || getQualifiedSuperclassName(sup) == getQualifiedClassName(Object)) 
    { 
     throw new Error("Given class is not a subclass of EngineObject!"); 
    } 

    return validateClass(sup); 
} 

Answer 2

あなたはどのタイプがから延びたクラスのすべてを把握するためにdescribeTypeを使用し、他の興味深いものがたくさんできました。

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/utils/package.html#describeType()

describeTypeあなたがクラスについて知りたいと思いますほとんどすべてを持つXMLを返します。 extendsClassというすべての要素をループし、その属性のtypeとあなたが選んだクラス名を比較するだけです。クラス名を調べるには、比較対象の型にgetQualifiedClassNameを使用してください。

Answer 3

function validateClass($class:Class):EngineObject { 
    var qn:String = getQualifiedClassName($class); 
    var en:String = getQualifiedClassName(EngineObject); 
    while(qn != "Object") { 
     if(qn == en) return new $class(); 
     qn = getQualifiedSuperclassName(getDefinitionByName(qn)); 
    } 
    throw new Error("Given class is not a subclass of EngineObject!"); 
} 

ここでのアイデアは、スーパークラスの修飾名を取得し、EngineObjectの修飾名と比較されます。一致しない場合は、スーパークラスが新しいクラス名として設定され、ループが再度実行されます。修飾されたスーパークラス名がObjectの場合は、それ以上の祖先がないことがわかります。