コードをループして、EまたはFの3つの値と、A、B、C、またはDの2つの値を返します。

Question

「E」または「F」の3つの値を返すコードを実行します。AND A、B、C、Dの2つの値も返します。ここまではこれまでのことです。

Sheets("123").Select 
Dim rng As Range 
Dim count As Integer 

Set rng = Range("L2:L500000") 
For Each cell In rng 
    If Left(cell.Value, 1) = "A" Or Left(cell.Value, 1) = "B" Or _ 
     Left(cell.Value, 1) = "C" Or Left(cell.Value, 1) = "D" Or _ 
     Left(cell.Value, 1) = "E" Or Left(cell.Value, 1) = "F" Then 
     cell.EntireRow.Interior.ColorIndex = 4 
     count = count + 1 
    End If 
    If count >= 5 Then Exit For 
Next 

Answer 1

A、B、C、DとE、Fの2つのカウンターを1つずつ保持する必要があります。あなたの質問に基づいて

（あなたのコメントに与えられていない矛盾した数字）、以下はあなたが欲しいものを行う必要があります。

Dim cell As Range 
Dim countABCD As Integer 
Dim countEF As Integer 
For Each cell In Worksheets("123").Range("L2:L500000") 
    Select Case Left(cell.Value, 1) 
     Case "A", "B", "C", "D" 
      If countABCD < 2 Then 
       cell.EntireRow.Interior.ColorIndex = 4 
       countABCD = countABCD + 1 
      End If 
     Case "E", "F" 
      If countEF < 3 Then 
       cell.EntireRow.Interior.ColorIndex = 4 
       countEF = countEF + 1 
      End If 
    End Select 
    If countABCD = 2 And countEF = 3 Then 
     Exit For 
    End If 
Next