他のブックにデータをコピーするときにVBA Excelが応答しない

Question

この単純なコードを使用して、ブック1からブック2を同じフォルダにコピーします。

Sub Button27_Click() 
    Application.ScreenUpdating = False 
    Dim FileName As String 
    Workbooks.Open FileName:=ActiveWorkbook.Path & "\sefaresh.xlsm" 
    Application.Wait (Now + TimeValue("0:00:01")) 
    ThisWorkbook.Sheets("Sheet3").Copy 
    After:=Workbooks("sefaresh.xlsm").Sheets(Sheets.Count) 
    Application.ScreenUpdating = True 
End Sub 

コピー&ペースト機能プロセスに成功したが、私は最初のワークブック2を閉じた場合、私はExcelの応答がありませんます。なにか提案を？

おかげ

Answer 1

は（テストされていない）、これを試してみてください。あなたは今エラーを出すべきではありません。あなたがオブジェクトで作業する場合

物事は簡単になっ:)

Sub Button27_Click() 
    Dim wbThis As Workbook, wbThat As Workbook 
    Dim ws As Worksheet 
    Dim fName As String 

    On Error GoTo Whoa 

    Set wbThis = ThisWorkbook 
    Set ws = wbThis.Sheets("Sheet3") 

    fName = wbThis.Path & "\sefaresh.xlsm" 

    Application.ScreenUpdating = False 

    Set wbThat = Workbooks.Open(fName) 

    DoEvents 

    ws.Copy After:=wbThat.Sheets(wbThat.Sheets.Count) 

    '~~> close and save the workbook 
    wbThat.Close (True) 

    DoEvents '<~~ Give time for it to save and close 

LetsContinue: 
    Application.ScreenUpdating = True 
    MsgBox "Done" 
    Exit Sub 
Whoa: 
    MsgBox Err.Description 
    Resume LetsContinue 
End Sub