ランダムにイベントを呼び出す

Question

私はPictureBoxN_Clickイベントをランダムに呼び出す必要があります。どうすればvb.netでこれを行うことができますか？

Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click 
    If ListView1.Items.Count > 0 Then 
     If IsNothing(Me.ListView1.FocusedItem) Then 
      ListView1.TopItem.Selected = True 
     End If 
     For Each file As ListViewItem In ListView1.Items 
      Dim filePath As String = file.SubItems(1).Text & "\" & file.Text 
      If file.Selected = True Then 
       Process.Start(filePath) 
      End If 
     Next 
    Else 
     Dim rndm As Integer = CInt(Math.Ceiling(Rnd() * 20)) + 1 
     Dim rndpic As String = "PictureBox" & rndm & "_Click" 
     Call rndpic(Nothing, Nothing) 
    End If 
End Sub 

Answer 1

私はjmcilhinneyの答えに同意しますが、ここで最初に求めたことを行う方法があります。これは、Controls.Find（）を使用して、 "名前で"目的のPictureBoxへの参照を取得する方法も示しています。 Reflectionを使用して一致するメソッド名を探し、Invoke（）を呼び出しています：

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
    Static R As New Random 
    Dim rndm As Integer = R.Next(1, 91) ' <-- return a value between 1 and 90 inclusive (yes, 91 is correct!) 
    Dim ctlName As String = "PictureBox" & rndm.ToString 
    Dim methodName As String = ctlName & "_Click" 
    Dim flags As Reflection.BindingFlags = Reflection.BindingFlags.IgnoreCase Or Reflection.BindingFlags.Instance Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.NonPublic 
    Dim MI As _MethodInfo = Me.GetType.GetMethod(methodName, flags) 
    If Not IsNothing(MI) Then 
     Dim matches() As Control = Me.Controls.Find(ctlName, True) 
     If matches.Length > 0 AndAlso TypeOf matches(0) Is PictureBox Then 
      Dim pb As PictureBox = DirectCast(matches(0), PictureBox) 
      MI.Invoke(Me, New Object() {pb, New EventArgs}) 
     End If 
    End If 
End Sub 

Answer 2

まず、イベントを呼び出していません。イベントはあなたによってではなく発生します。 PictureBoxでClickイベントを発生させる唯一の簡単な方法は、マウスでクリックすることです。

あなたが話しているのは、メソッドを呼び出すことです。イベントハンドラはイベントではありません。イベントハンドラは、イベントが発生したときに自動的に実行されるメソッドです。イベントハンドラを直接呼び出すことは、実際には貧弱な方法です。

実行するコードは、PictureBoxというパラメータを持つ独自のメソッドに入れてください。その後、PictureBoxesのイベントハンドラClickからそのメソッドを呼び出すことができます。あなたがそうするならば、あなたはこの場合のどんなClickイベントについても考える必要はなく、それはどのようにすべきかです。クリックが行なわれていないからです。

PictureBoxのそれぞれについて同じことをしている場合は、すべてのPictureBoxesに対して1つのイベントハンドラのみが必要です。ランダムPictureBoxのコードを実行する場合は、Buttonをクリックし、ランダムPictureBoxを選択してメソッドに渡します。例えば。

Private rng As New Random 

Private Sub PictureBoxes_Click(sender As Object, e As EventArgs) Handles PictureBox3.Click, 
                     PictureBox2.Click, 
                     PictureBox1.Click 
    'Prcoess the PictureBox that was clicked. 
    ProcessPictureBox(DirectCast(sender, PictureBox)) 
End Sub 

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
    'Process a random PictureBox. 

    Dim pictureBoxes = {PictureBox1, PictureBox2, PictureBox3} 
    Dim pictureBox = pictureBoxes(rng.Next(pictureBoxes.Length)) 

    ProcessPictureBox(pictureBox) 
End Sub 

Private Sub ProcessPictureBox(pictureBox As PictureBox) 
    'Use pictureBox here. 
End Sub