AESON-Haskellの任意のJSONキー

Question

私は、任意のキーを持つ入れ子になったJSONオブジェクトをたくさん持っています。 Aは、B、Cが前もって分かっていない

{ 
    "A": { 
     "B": { 
      "C": "hello" 

     } 
    } 

} 

。それらの3つのそれぞれは に兄弟を持つこともできます。

これをAesonのカスタムタイプに解析する方法があるかどうかは、私が考えているのは、 です。私がやっているのは、それをAeson Objectにロードすることです。

この種類のJSON オブジェクトに対して、FromJSONを実装する方法を教えてください。

ありがとうございます！

編集：

{ 
    "USA": { 
     "California": { 
      "San Francisco": "Some text" 
     } 
    }, 
    "Canada": { 
     ... 
    } 
} 

これは...

type City   = Map String String 
type Country   = Map String City 
type CountryDatabase = Map String Country 

Answer 1

あなたはMap String vのFromJSONインスタンスを再利用することができCountryDatabaseにコンパイルする必要があります。次のような何か：

{-# LANGUAGE OverloadedStrings #-} 

import Data.Functor 
import Data.Monoid 
import Data.Aeson 
import Data.Map (Map) 
import qualified Data.ByteString.Lazy as LBS 
import System.Environment 

newtype City = City (Map String String) 
    deriving Show 

instance FromJSON City where 
    parseJSON val = City <$> parseJSON val 

newtype Country = Country (Map String City) 
    deriving Show 

instance FromJSON Country where 
    parseJSON val = Country <$> parseJSON val 

newtype DB = DB (Map String Country) 
    deriving Show 

instance FromJSON DB where 
    parseJSON val = DB <$> parseJSON val 

main :: IO() 
main = do 
    file <- head <$> getArgs 
    str <- LBS.readFile file 
    print (decode str :: Maybe DB) 

出力：

shum@shum-lt:/tmp/shum$ cat in.js 
{ 
    "A": { 
     "A1": { 
      "A11": "1111", 
      "A22": "2222" 
     } 
    }, 
    "B": { 
    } 
} 
shum@shum-lt:/tmp/shum$ runhaskell test.hs in.js 
Just (DB (fromList [("A",Country (fromList [("A1",City (fromList [("A11","1111"),("A22","2222")]))])),("B",Country (fromList []))])) 
shum@shum-lt:/tmp/shum$ 

PS：あなたは私だけ明確にするためにそれらを使用し、newtype Sなしでそれを行うことができます。