ユーザー入力を検証するvba

Question

次のユーザー入力をExcel vbaでセットアップしました。この関数は、呼び出されたときに9999以下の単一の数値を入力するか、2つの数字がダッシュで区切られた形式のXXXX-XXXXの2つの数値を入力するようにユーザーに求めます。その場合、数字はどちらの場合も9999を超えることはできません。

目的は、単一の数値（IE 50）または範囲（IEの低い値は50、高い値は75）を返すことです。現在セットアップされているように、配列の最初の位置が低い値で、2番目の位置が高い値を返すはずです。または、ユーザーが1つの番号だけを入力する場合は、配列の最初の位置に1つの番号を戻す必要があります。

現在、A）ユーザーが数字を入力したこと、B）数字が4桁以下であることを確認しています。

残念ながら、配列を返していないため、エラーが返されています。下付き文字は範囲外です。

また、ここでチェックする必要がある可能性のある他のユーザー入力がありますか？このアプリケーションは人によって広く使われることはありませんが、潜在的なエラーも最小限に抑えたいと思います。

Public Function getUserInput() As Variant 
'this function gets a user input from an input box and puts it out into the proper format 


     Dim inputString As String 
     Dim numArr() As String 

     Dim i As Long 

     ' On Error GoTo NotValidInput 
     inputString = Trim(InputBox("Enter the rows you'd like to print")) 

     'has the user entered a dash into their user input 

     If InStr(inputString, "-") > 0 Then 
       numArr() = Split(inputString, "-") 

       If UBound(numArr) <> 1 Then 
        GoTo NotValidNumberFormat 
       End If 
       If (IsNumeric(numArr(0)) And Len(numArr(0)) <= 4) And (IsNumeric(numArr(1)) And Len(numArr(1)) <= 4) Then 

        getUserInput = numArr 
        Exit Function 
       Else 
        GoTo NotValidNumberFormat 
       End If 
     'no dash 
     '60 

     Else 
      If (IsNumeric(CInt(inputString))) And Len(inputString) <= 4 Then 
        getUserInput = numArr 
       Exit Function 
      Else 
       GoTo NotValidNumberFormat 
      End If 
     End If 


Exit Function 

NotValidNumberFormat: 
'if the conversion failed, return error 
MsgBox ("Please enter the number in a valid format - either a single number no larger than 9999 or two numbers no larger than 9999 separated by only one dash (IE XX-XX)") 

getUserInput = -1 

End Function 

Answer 1

これが何をすべき：

Public Function getUserInput() As Variant 
    'this function gets a user input from an input box and puts it out into the proper format 
    Dim numArr As Variant 
    Dim goOn As Boolean 

    Do 
     numArr = Split(WorksheetFunction.Trim(InputBox("Enter the rows you'd like to print in the format 'nnnn' or 'nnnn-mmmm'")), "-") 
     Select Case UBound(numArr) 
      Case 0 
       goOn = Format(numArr(0), "0000") Like "####" 
      Case 1 
       goOn = Format(numArr(0), "0000") Like "####" And Format(numArr(1), "0000") Like "####" 
     End Select 
     If Not goOn Then MsgBox "Please enter the number in a valid format - either a single number no larger than 9999 or two numbers no larger than 9999 separated by only one dash (ex: XX-XX)"   
    Loop While Not goOn 
    getUserInput = numArr 
End Function