更新/再起動後のWindowsサーバーの時刻が正しくない

Question

Windows Server 2012 R2を実行しています。サーバーがアップデートをインストールして再起動すると（毎日午前4時に）、不正なタイムゾーンで再起動します。私たちの時間サイズはEST -5（現在は夏時間の-4）であり、サーバーのデフォルトはUTC -0です。これは私たちのタイムゾーンより4時間早いです。

最初にこの問題を発見したとき、実際には唯一の回避策は、サーバーを再起動したときにタスクスケジューラを使用してsyncコマンドを実行することでした。そのタスクとコマンドは、2週間前、2014年6月15日頃までうまくいきました。それ以来、うまくいきませんでした。私はタスク/イベントログを見直しましたが、正常に実行されたと主張していますが、それはまだありません。

私の唯一の考えは、Windowsのアップデートでは、同期コードが役に立たないものがあったということです。しかし、私はそれができることを失っています。誰かが問題の特定方法に関する提案をしていますか？

使用している同期コードは.batファイルです。

2017-06 Windows Server 2012 R2 for x64ベースシステムのセキュリティロールアップ（月額6,000円） （KB4022726）は

は のWindows 8、8.1、10およびWindows Server 2012、2012 R2、2016のx64 Edition用

Windows悪意のあるソフトウェアの削除ツール - 2017年6月（KB890830）は

REM *** Retry for up to 15 minutes (90 retries @ 10 seconds each) 
set retryCount=0 

:SyncStart 
if %retryCount == 90 goto SyncEnd 
set /A retryCount=retryCount + 1 

REM *** Resync the system clock 
net start w32time 
w32tm /resync 
if errorlevel 1 goto SyncDelay 
if errorlevel 0 goto SyncEnd 

:SyncDelay 
REM *** If unsuccessful, delay 10 seconds, then retry 
choice /n /t:y,10>nul 
goto SyncStart 

:SyncEnd 

Answer 1

バッチファイルには、構文エラーが含まれていますインライン：

if %retryCount == 90 goto SyncEnd 

環境変数の値は、標準的な膨張等だけでなく%VariableNameを使用して%VariableName%で参照しなければならないループ変数（CMDそれぞれ%%Iバッチファイル内に%I）またはバッチファイル引数（%0、%1 FOR 、...）、または!VariableName!（ここでは不要な遅延拡張を使用してください）。

コードも最適化することができます

@echo off 
REM *** Retry for up to 15 minutes (90 retries @ 10 seconds each) 
set retryCount=0 

:SyncStart 
if %retryCount% == 90 goto :EOF 
set /A retryCount+=1 

REM *** Resync the system clock 
%SystemRoot%\System32\net.exe start w32time 
%SystemRoot%\System32\w32tm.exe /resync 
if not errorlevel 1 goto :EOF 

REM *** If unsuccessful, delay 10 seconds, then retry 
%SystemRoot%\System32\timeout.exe 10 /nobreak 
goto SyncStart 

まあ、コードをさらに最適化することができます。

@echo off 
REM *** Retry for up to 15 minutes (90 retries @ 10 seconds each) 
set retryCount=0 
%SystemRoot%\System32\net.exe start w32time 
%SystemRoot%\System32\timeout.exe 5 /nobreak 

:SyncTime 
%SystemRoot%\System32\w32tm.exe /resync 
if not errorlevel 1 goto :EOF 

REM *** If unsuccessful, delay 10 seconds, then retry 
set /A retryCount+=1 
if not %retryCount% == 90 %SystemRoot%\System32\timeout.exe 10 /nobreak & goto SyncTime 

使用されるコマンドとその仕組みを理解するために、コマンドプロンプトウィンドウを開きますそこで次のコマンドを実行し、各コマンドに表示されるすべてのヘルプページを非常に注意深く読んでください。

• echo /?
• goto /?
• if /?
• net /?
• net start /?
• rem /?
• set /?
• timeout /?
• w32tm /?

そして、Microsoftのサポート記事Testing for a Specific Error Level in Batch Filesをお読みください。