VB.net

Question

を使用してXMLタグを読み取るための正しいパスをフォーマット私は、次のコード

Imports System.Xml 

Public Class Form1 

    Private Sub Convert_Button_Click(sender As Object, e As EventArgs) Handles Convert_Button.Click 
     Dim doc As New XmlDocument() 
     doc.Load("C:\Test\Inventory.xml") 
     Dim nodes As XmlNodeList = doc.DocumentElement.SelectNodes("/IXFleet/SyncData/Transaction") 
     Dim product_id As String = "", product_name As String = "", product_price As String = "" 
     For Each node As XmlNode In nodes 
      product_id = node.SelectSingleNode("SiteID").InnerText 
      product_name = node.SelectSingleNode("TankID").InnerText 
      product_price = node.SelectSingleNode("TankNumber").InnerText 
      MessageBox.Show(product_id & " " & product_name & " " & product_price) 
     Next 
    End Sub 

End Class 

を使用しようとしていますそして、私は、次のXMLデータに

<IXFleet> 
    <SyncConfig xmlns="http://tempuri.org/SyncConfig.xsd"/> 
    <SyncData xmlns="http://tempuri.org/SyncData.xsd"> 
    <Transaction> 
    <SiteID>1</SiteID> 
    <TankID>1</TankID> 
    <TankNumber>1</TankNumber> 
    </Transaction> 
    </SyncData> 
</IXFleet> 

私の問題を読みしようとしています実際にトランザクションノードに到達して、SiteID、TankID、およびTankNumberを読み取るために、このコードセクションを適切にフォーマットする方法（具体的には、タグパスのSyncData部分）を知りませんか。

XMLファイルのSyncDataノードで余分なデータ（xmlns = "http://tempuri.org/SyncData.xsd"）を手作業で削除し、そのパスをVBコードでそのまま使用すると、余分なデータをXMLに戻すと、データが見つからなくなります。

ご協力いただければ幸いです。

Answer 1

NamespaceManagerが必要です。その後、名前空間接頭辞を持つすべてのクエリを実行し、マネージャーを渡します。

Dim doc As New XmlDocument() 
    doc.Load("C:\Test\Inventory.xml") 
    Dim nsmgr = New XmlNamespaceManager(doc.NameTable) 
    nsmgr.AddNamespace("sd", "http://tempuri.org/SyncData.xsd") 
    Dim nodes As XmlNodeList = doc.DocumentElement.SelectNodes("/IXFleet/sd:SyncData/sd:Transaction", nsmgr) 
    Dim product_id As String = "", product_name As String = "", product_price As String = "" 
    For Each node As XmlNode In nodes 
     product_id = node.SelectSingleNode("sd:SiteID", nsmgr).InnerText 
     product_name = node.SelectSingleNode("sd:TankID", nsmgr).InnerText 
     product_price = node.SelectSingleNode("sd:TankNumber", nsmgr).InnerText 
     MessageBox.Show(product_id & " " & product_name & " " & product_price) 
    Next