icaclsが括弧で括られています

Question

これは実際には動作していますが、私が好む形式ではありません。以下のコードは私が望むものを達成します。書き込み可能な標準ユーザープロファイルのフォルダを作成します（Defaultなどのシステムプロファイルでは動作しません）、一部のソフトウェアに必要なものがあり、関連する権限が与えられます。

for /d %%A in ("C:\Users\*") do mkdir "%%~fA\AppData\Local\Folder1" 
for /d %%A in ("C:\Users\*") do mkdir "%%~fA\AppData\Local\Folder1_Ltd" 
for /d %%A in ("C:\Users\*") do icacls "%%~fA\AppData\Local\Folder1" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 
for /d %%A in ("C:\Users\*") do icacls "%%~fA\AppData\Local\Folder1_Ltd" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 

これは少し上のようです。私はちょうどユーザーのフォルダを介して1つのループを持っているし、すべての関数のユーザーループを保存、コマンドを一覧表示するために角かっこを使用したいと思います。しかし、私が以下を試してみると、フォルダを作ることさえできません。私がコマンドラインを使ってデバッグすると、この時点で "everyone"が予期しなかったところで停止します。なぜわからないのですか？どんなアドバイスも歓迎します、ありがとう。

for /d %%A in ("C:\Users\*") do (
mkdir "%%~fA\AppData\Local\Folder1" 
mkdir "%%~fA\AppData\Local\Folder1_Ltd" 
icacls "%%~fA\AppData\Local\Folder1" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 
icacls "%%~fA\AppData\Local\Folder1_Ltd" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 
) 
pause 

Answer 1

あなたものみ、通常のユーザープロファイルにアクセスするためにWMIを使用することができます。

@Echo Off 
For /F "Skip=1 Delims=" %%A In (
    '"WMIc Path Win32_UserProfile Where (Special!='True') Get LocalPath"' 
    ) Do For /F "Delims=" %%B In ("%%A") Do Call :Sub %%B 
Pause>Nul 
GoTo :EOF 

:Sub 
For %%A In (Folder1 Folder1_Ltd) Do (If Not Exist "%*\AppData\Local\%%A\" (
     MD "%*\AppData\Local\%%A") 
    ICACLS "%*\AppData\Local\%%A" /T /C /Q /grant:r Everyone:(OI^)(CI^)F /inheritance:e) 

Answer 2

（コードブロック）内の閉じ括弧をすべてエスケープして、ブロックの最後と解釈しないようにする必要があります。

for /d %%A in ("C:\Users\*") do (
    mkdir "%%~fA\AppData\Local\Folder1" 
    mkdir "%%~fA\AppData\Local\Folder1_Ltd" 
    icacls "%%~fA\AppData\Local\Folder1" /T /C /grant(:r^) "Everyone":(OI^)(CI^)(F^) /inheritance:e 
    icacls "%%~fA\AppData\Local\Folder1_Ltd" /T /C /grant(:r^) "Everyone":(OI^)(CI^)(F^) /inheritance:e 
) 
pause 

編集eryksunは、サブルーチンを使用する代替手段です示唆したとして（^エスケープを挿入するために、エディタを使用すると、大したことないですが）

@Echo off 
for /d %%A in ("C:\Users\*") do Call :Sub "%%~fA" 
pause 
Goto :Eof 
:Sub 
mkdir "%~f1\AppData\Local\Folder1" 
mkdir "%~f1\AppData\Local\Folder1_Ltd" 
icacls "%~f1\AppData\Local\Folder1" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 
icacls "%~f1\AppData\Local\Folder1_Ltd" /T /C /grant(:r) "Everyone":(OI)(CI)(F) /inheritance:e 

Answer 3

別の方法としては、不要な括弧を削除することができ、必要なものを引用する

カッコgrantスイッチであり、その後のことができます

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for /d %%A in ("C:\Users\*") do (
     for %%F in ("%%~fA\AppData\Local\Folder1" "%%~fA\AppData\Local\Folder1_Ltd") do (
      mkdir "%%~fF" 
      icacls "%%~fF" /T /C "/grant(:r)" "Everyone":"(OI)(CI)(F)" /inheritance:e 
     ) 
    ) 

ノート：（/grant場合）引用された引数に対処するためのicacls habilityがある場合は、Windows 10上で試験した両方の例は、私はこの時点でテストすることはできません以前のOSバージョンに存在します。注2

：icacls.exeのWindows 2003のサーバーSP2バージョン（最初のバージョンに公開）で（まあ、/inheritanceスイッチが存在していなかった）問題なくテストされています。 eryksunが指摘するように、追加の引用符はCRTによって削除されます。