Delphis MessageDlgでタイマーイベントを無視する方法

Question

私はDelphiでグローバル例外ハンドラを設定しました。重大な例外を除いて、エラーメッセージが表示されます（Halt（）が続きます）。エラーメッセージが表示されている間、Delphiはエラーをさらに引き起こすタイマーイベントを処理しているメッセージキューを処理しています。

私が欲しいのは、タイマーイベントを処理しないエラーダイアログを表示することです。 Delphiではどのように可能ですか？

編集：私はDialogs.MessageDlg（...）を使ってメッセージを表示します。

Answer 1

あなたがTApplication.OnMessageで、このようWM_TIMERとしてキューに入れられたメッセージをフィルタリングすることができます。

procedure TMainForm.ApplicationMessage(var Msg: TMsg; var Handled: Boolean); 
begin 
    if ShowingFatalErrorDialog then 
    if Msg.Message = WM_TIMER then 
     Handled := True; 
end; 

Application.OnMessageに直接そのイベントハンドラを割り当てるかTApplicationEventsオブジェクトを使用しますか。

具体的には、ShowingFatalErrorDialogの実装を提供する必要がありますが、私はそれを行う方法は明らかです。

Answer 2

はこのような何かを試してみてください：

... 
    private 
    FAboutToTerminate: Boolean; 
    end; 

... 

type 
    ESevereError = class(Exception); 

procedure TForm1.Timer1Timer(Sender: TObject); 
begin 
    Tag := Tag + 1; 
    if Tag > 2 then 
    raise ESevereError.Create('Error'); 
end; 

procedure TForm1.ApplicationEvents1Exception(Sender: TObject; 
    E: Exception); 
begin 
    if (E is ESevereError) and (not FAboutToTerminate) then 
    begin 
    FAboutToTerminate := True; 
    Application.ShowException(E); 
    Application.Terminate; 
    end; 
end; 

Answer 3

ちょうど参考のために、次のコードを使用します。これは両方の回答が混在しています。 TFatalErrorAppEventsで

procedure SaveShowErrorMessage(...) 
begin 
    with TFatalErrorAppEvents.Create(nil) do //avoid timer and further exceptions 
    try 
     Dialogs.MessageDlg(...); 
    finally 
     Free; 
    end; 
end; 

は、次のように：

type 
    TFatalErrorAppEvents = class(TApplicationEvents) 
    protected 
     procedure KillTimerMessages(var Msg: tagMSG; var Handled: Boolean); 
     procedure IgnoreAllExceptions(Sender: TObject; E: Exception); 
    public 
     constructor Create(AOwner: TComponent); override; 
    end; 


constructor TFatalErrorAppEvents.Create(AOwner: TComponent); 
begin 
    inherited; 
    OnMessage := KillTimerMessages; 
    OnException := IgnoreAllExceptions; 
end; 

procedure TFatalErrorAppEvents.IgnoreAllExceptions(Sender: TObject; E: Exception); 
begin 
    //in case of an Exception do nothing here to ignore the exception 
end; 

procedure TFatalErrorAppEvents.KillTimerMessages(var Msg: tagMSG; var Handled: Boolean); 
begin 
    if (Msg.message = WM_TIMER) then 
     Handled := True; 
end;