GHC.Generics（または他の同様のフレームワーク）を使用して汎用Functorインスタンスを構築する方法は？

Question

私はGHC Genericsを学ぼうとしています。いくつかの例を見直した後、汎用のFunctorインスタンスを作成しようとしました（GHCが自動的にそれらを引き出すことはできません）。しかし、ジェネリックスでパラメータ化されたデータ型をどのように扱うか分かりません。私が見た例はすべて*です。これは可能ですか？はいの場合、どうですか？ （私はSYBのような他の同様のフレームワークにも興味があります）

Answer 1

GHCジェネリックスを使用してたくさんのサンプル関数を探すには、generic-deriving packageが最適です。そこにはFunctorクラスの一般的な定義があります。 Generics.Deriving.Functorからのコピー（少し簡略化）：

class GFunctor' f where 
    gmap' :: (a -> b) -> f a -> f b 

instance GFunctor' U1 where 
    gmap' _ U1 = U1 

instance GFunctor' Par1 where 
    gmap' f (Par1 a) = Par1 (f a) 

instance GFunctor' (K1 i c) where 
    gmap' _ (K1 a) = K1 a 

instance (GFunctor f) => GFunctor' (Rec1 f) where 
    gmap' f (Rec1 a) = Rec1 (gmap f a) 

instance (GFunctor' f) => GFunctor' (M1 i c f) where 
    gmap' f (M1 a) = M1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :+: g) where 
    gmap' f (L1 a) = L1 (gmap' f a) 
    gmap' f (R1 a) = R1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :*: g) where 
    gmap' f (a :*: b) = gmap' f a :*: gmap' f b 

instance (GFunctor f, GFunctor' g) => GFunctor' (f :.: g) where 
    gmap' f (Comp1 x) = Comp1 (gmap (gmap' f) x) 


class GFunctor f where 
    gmap :: (a -> b) -> f a -> f b 
    default gmap :: (Generic1 f, GFunctor' (Rep1 f)) 
       => (a -> b) -> f a -> f b 
    gmap = gmapdefault 

gmapdefault :: (Generic1 f, GFunctor' (Rep1 f)) 
      => (a -> b) -> f a -> f b 
gmapdefault f = to1 . gmap' f . from1 

データ型でこれを使用するには、むしろGenericよりGeneric1を導出する必要があります。 Generic1表現の主な違いは、パラメータ位置をエンコードするPar1データ型を使用することです。

Answer 2

データタイプが* -> *の場合、Generic1クラスがあります。これを使用した作業は、ほとんどの場合、種類が*のデータ型と同じですが、パラメータにはPar1があります。私は例えばunfoldable packageに使っています。