SQL Serverのすべての挿入ステートメントに固有のIDを生成する方法はありますか？

Question

私が作るすべての挿入ステートメントに一意のIDを与えたいので、これは一緒に挿入された行を確認することができます。一意の「挿入ID」が1から始まり、行数がIDENTITY(1,1)のように1ずつ増加することをお勧めします。

IDENTITYのような簡単な方法はありますか？

CREATE TABLE [dbo].[factTrade] 
(
     [ID] [int] IDENTITY(1,1) NOT NULL, 
     [insertedID] [int] NOT NULL, 
     [quantity] [int] NOT NULL, 
     [price] [decimal](20, 10) NOT NULL 
) 

INSERT INTO [dbo].[factTrade] ([insertedID], [quantity], [price]) 
VALUES (1, 6, 2.5), (1, 4, 3.7), (1, 3, 4.1), (1, 7, 8.5), 

INSERT INTO [dbo].[factTrade] ([insertedID], [quantity], [price]) 
VALUES (2, 5, 5.2), (2, 1, 4.6) 

Answer 1

これはあなたが尋ねたソリューションではありませんが、あなたは、同時に挿入されたすべての行を見つけるために、デフォルトのタイムスタンプを持つ列を追加することができます。

ALTER TABLE dbo.factTrade 
ADD InsertDate DATETIME NOT NULL DEFAULT (GETDATE()) 

Answer 2

あなたは整数値が必要な場合は、その後、あなたは別のテーブルを作成することができます。

CREATE TABLE inserts ([ID] INT IDENTITY(1,1)...) 

次に、あなたのアプリから、このに行を挿入し、生成されたID値（SCOPE_IDENTITY()）を使用します。

INSERT inserts DEFAULT VALUES; 
SELECT @insertId = SCOPE_IDENTITY(); 

Answer 3

GUIDはそのようなことのために便利です。

declare @insertid uniqueidentifier = newid(); 
CREATE TABLE [dbo].[factTrade](
    [ID] [int] IDENTITY(1,1) NOT NULL, 
    [insertedID] [int] NOT NULL, 
    [quantity] [int] NOT NULL, 
    [price] [decimal](20, 10) NOT NULL, 
    [insertid] [uniqueidentifier] not null 
) 

INSERT INTO [dbo].[factTrade] 
    ([insertedID] 
    ,[quantity] 
    ,[price] 
    ,[insertid] 
) 
VALUES 
    (1, 6, 2.5,@insertid), 
    (1, 4, 3.7,@insertid), 
    (1, 3, 4.1,@insertid), 
    (1, 7, 8.5,@insertid) 
set @insertid = newid(); --get another guid 
INSERT INTO [dbo].[factTrade] 
    ([insertedID] 
    ,[quantity] 
    ,[price] 
    ,[insertid] 
) 
VALUES 
    (2, 5, 5.2,@insertid), 
    (2, 1, 4.6,@insertid) 

Answer 4

これは私がやったことです。すべての提案とコメントに感謝します。

DECLARE @insertedID INT 

CREATE TABLE [dbo].[factTrade] 
(
     [ID] [int] IDENTITY(1,1) NOT NULL, 
     [insertedID] [int] NOT NULL, 
     [quantity] [int] NOT NULL, 
     [price] [decimal](20, 10) NOT NULL 
) 

CREATE SEQUENCE [dbo].[factTradeInsertedID] AS INT 
    START WITH 1 
    INCREMENT BY 1 

SET @insertedID = NEXT VALUE FOR [dbo].[factTradeInsertedID] --1 

INSERT INTO [dbo].[factTrade] 
      ([insertedID] 
      ,[quantity] 
      ,[price]) 
    VALUES 
      (@insertedID, 6, 2.5) 
      ,(@insertedID, 4, 3.7) 
      ,(@insertedID, 3, 4.1) 
      ,(@insertedID, 7, 8.5) 


SET @insertedID = NEXT VALUE FOR [dbo].[factTradeInsertedID] --2 

INSERT INTO [dbo].[factTrade] 
      ([insertedID] 
      ,[quantity] 
      ,[price]) 
    VALUES 
      (@insertedID, 5, 5.2) 
      ,(@insertedID, 1, 4.6)