GpuMat - カスタムカーネルで2チャンネルフロートデータにアクセスする

Question

cv::cuda::PtrStepは、GpuMatのデータをカスタムカーネルに直接渡すために使用されています。私は1チャンネルアクセスの例を見つけたhereしかし私の場合は2チャンネルのマット（CV_32FC2）です。この場合、複素数値が次のようにコード化されている複素絶対二乗値を達成しようとしています。実数部は第1面、虚数部は第2面であるMatです。

私が試した：

__global__ void testKernel(const cv::cuda::PtrStepSz<cv::Vec2f> input, cv::cuda::PtrStepf output) 
{ 
    int x = blockIdx.x * blockDim.x + threadIdx.x; 
    int y = blockIdx.y * blockDim.y + threadIdx.y; 

    if (x <= input.cols - 1 && y <= input.rows - 1 && y >= 0 && x >= 0) 
    { 
     float val_re = input(x, y)[0]; 
     float val_im = input(x, y) [1]; 
     output(x, y) = val_re * val_re + val_im * val_im; 
    } 
} 

をが、これは、次のエラーが発生：

calling a __host__ function("cv::Vec<float, (int)2> ::operator []") from a __global__ function("gpuholo::testKernel") is not allowed 

は、私はそれを取得します。 []はcv::Vec2fではなく、cv::cuda::Vec2f（明らかに存在しない）のため、制限された機能である__host__です。しかし、私は本当にデータにアクセスしたいと思っています。

Vec2fのようなデバイス側の2チャネルデータにアクセスする他のメカニズムはありますか？

__global__ void testKernel(const cv::cuda::PtrStepSzf re, const cv::cuda::PtrStepSzf im, cv::cuda::PtrStepf output) 

が、私は、「クリーンな」解決策があるのか​​どうか迷っVec2fだ：カーネルは次のようになりますので、私はinputMatCV_32FC1 2にSを分割する形での回避策を考え

---

のようなものです。

Answer 1

カスタムCUDAカーネルのGpuMatのデータに生データ型を使用してアクセスできます。例えばCUDAランタイムによって提供されるfloat2タイプは、cv::Vec2fの部分置換として使用できます。次に、GpuMatデータにアクセスするための生データ型の使用法を示すコード例を示します。

#include <iostream> 
#include <cuda_runtime.h> 
#include <opencv2/opencv.hpp> 

using std::cout; 
using std::endl; 

__global__ void kernel_absolute(float2* src, float* dst, int rows, int cols, int iStep, int oStep) 
{ 
    int i = blockIdx.y * blockDim.y + threadIdx.y; //Row number 
    int j = blockIdx.x * blockDim.x + threadIdx.x; //Column number 

    if (i<rows && j<cols) 
    { 
     /* Compute linear index from 2D indices */ 
     int tidIn = i * iStep + j; 
     int tidOut = i * oStep + j; 

     /* Read input value */ 
     float2 input = src[tidIn]; 

     /* Calculate absolute value */ 
     float output = sqrtf(input.x * input.x + input.y * input.y); 

     /* Write output value */ 
     dst[tidOut] = output; 
    } 
} 

int main(int argc, char** argv) 
{ 
    /* Example to compute absolute value of each element of a complex matrix */ 
    int rows = 10; 
    int cols = 10; 
    int input_data_type = CV_32FC2; //input is complex 
    int output_data_type = CV_32FC1; //output is real 

    /* Create input matrix on host */ 
    cv::Mat input = cv::Mat::zeros(rows,cols,input_data_type) + cv::Vec2f(1,1) /* Initial value is (1,1) */; 

    /* Display input */ 
    cout<<input<<endl; 

    /* Create input matrix on device */ 
    cv::cuda::GpuMat input_d; 
    /* Copy from host to device */ 
    input_d.upload(input); 

    /* Create output matrix on device */ 
    cv::cuda::GpuMat output_d(rows,cols, output_data_type); 

    /* Compute element step value of input and output */ 
    int iStep = input_d.step/sizeof(float2); 
    int oStep = output_d.step/sizeof(float); 

    /* Choose appropriate block size */ 
    dim3 block(8,8); 

    /* Compute grid size using input size and block size */ 
    dim3 grid ((cols + block.x -1)/block.x, (rows + block.y -1)/block.y); 

    /* Launch CUDA kernel to compute absolute value */ 
    kernel_absolute<<<grid, block>>>(reinterpret_cast<float2*>(input_d.data), reinterpret_cast<float*>(output_d.data), rows, cols, iStep, oStep); 

    /* Check kernel launch errors */ 
    assert(cudaSuccess == cudaDeviceSynchronize()); 

    cv::Mat output; 

    /* Copy results from device to host */ 
    output_d.download(output); 

    /* Display output */ 
    cout<<endl<<output<<endl; 

    return 0; 
} 

CUDA 8.0とUbuntuの14.04で以下のコマンドでコンパイルとテスト：

nvcc -o complex complex.cu -arch=sm_61 -L/usr/local/lib -lopencv_core

Answer 2

カーネルへのシングル入力で作業したい場合は、flatten your 2 channel image to a 1 channel imageとすることができます。

// test image 
Mat h_mat(Size(50,50),CV_32FC2,Scalar(0.0)); 

// Mat::reshape takes number of channels and rows, for your example 1,1 
Mat h_mat_flat = h_mat.reshape(1,1); 

// to upload to gpu 
GpuMat d_mat_flat(h_mat_flat.size(), h_mat_flat.type()); 
d_mat_flat.upload(h_mat_flat); 

今、あなたはPtrStepSzfとしてカーネルにd_mat_flatを渡すことができます。