オカレンスを変更せずにパッチのクラスタを作成する

Question

パッチのみを含むNetlogoモデルを作成しています。私は確率に応じて、6種類の色のパッチ（それぞれがプロジェクトの異なる植生を表す）からなる風景を作成することができました。したがって、赤いパッチは、各パッチに10％の確率、黄色の5％、褐色の20％というように発生する可能性があります。

この確率が設定されている私のコードの例は：

let i random-float 1 
    ifelse i + random-float 0.1 <= 0.8 ;random 0.1 threshold for environmental noise 
     [ set pcolor green ] 
     [ ifelse i + random-float 0.1 <= 0.9 
     [ set pcolor yellow ] 
     [ set pcolor blue ] ] 

しかしながら、これは、各色のランダムなパターンを生成します。しかし、私はそれらのうちの1つのためのクラスタ化された空間パターンを作成したいと思います。具体的には、私の風景では、茶色のパッチの割合を50％にします。しかし、すべてのパッチに対してこの確率を50％に設定すると、茶色のパッチがランダムに配布されます。どのように私の風景の50％を占めるようにするが、それはクラスタ化されたパターンで表示されますか？

ムーア近隣を使用してクラスターパターンを作成しようとしましたが、明らかに茶色のパッチの割合が変わります。

これはやや明確です。事前に助けてくれてありがとう。

Answer 1

あなたの体重に基づいて種を蒔き、種子の周りを育てることができます。色々なパッチをあなたの体重に基づいて色付けしてから、色をクラスター化します。

extensions [rnd] ;use the rnd extension 
globals [threshold] 

to setup 
    ca 
    set threshold 2 
    let _cw [[red 10] [yellow 20] [blue 70]] ;colors with weights 
    ask patches [set pcolor first rnd:weighted-one-of-list _cw [last ?]] 
    repeat 20 [cluster] ;adjust to taste 
end 

to cluster 
    ask patches [ 
    if unhappy? [ 
     swap-pcolor 
    ] 
    ] 
end 


to swap-pcolor 
    let _c pcolor 
    let _p one-of neighbors with [pcolor != [pcolor] of myself] 
    set pcolor [pcolor] of _p 
    ask _p [set pcolor _c] 
end 

to-report unhappy? 
    let _ct count neighbors with [pcolor = [pcolor] of myself] 
    report (_ct < threshold) 
end