エリクサーメッセージをアサートする方法

Question

メッセージを特定の順序で送信するエリクシールモジュールを構築しています。そして、私は問題がある。この

MyModule.send_msgs(self()) 
assert_received {:event, 1} 
assert_received {:event, 2} 
assert_received {:event, 3} 

のようなユニットテストを書いて、私はassert_received順序をシャッフルしても、テストはまだ合格します。

MyModule.send_msgs(self()) 
assert_received {:event, 2} 
assert_received {:event, 1} 
assert_received {:event, 3} 

assert_receivedは、メッセージ到着の順序を気にしないようです。 assert_receivedだけでなく、私が思い出す限り、receiveもメッセージが乱れることがあります。 ここで私の質問は、到着したメッセージが順序どおりに受信できない場合、その順序をどうやって保証できるのでしょうか？

Answer 1

あり、これを行うために、既存の機能のように見えるが、メールボックスに次のメッセージが特定のパターンと一致することを主張する独自のマクロ作るのは簡単ですしていません。

defmacro assert_next_receive(pattern, timeout \\ 100) do 
    quote do 
    receive do 
     message -> 
     assert unquote(pattern) = message 
    after unquote(timeout) -> 
     raise "timeout" # you might want to raise a better message here 
    end 
    end 
end 

テスト：

を

defmodule MTest do 
    use ExUnit.Case 

    def send_msgs(pid) do 
    send pid, {:event, 1} 
    send pid, {:event, 2} 
    send pid, {:event, 3} 
    end 

    defmacro assert_next_receive(pattern, timeout \\ 100) do 
    quote do 
     receive do 
     message -> 
      assert unquote(pattern) = message 
     after unquote(timeout) -> 
     raise "timeout" # you might want to raise a better message here 
     end 
    end 
    end 

    test "should pass" do 
    send_msgs(self()) 
    assert_next_receive {:event, 1} 
    assert_next_receive {:event, 2} 
    assert_next_receive {:event, 3} 
    end 

    test "should fail" do 
    send_msgs(self()) 
    assert_next_receive {:event, 1} 
    assert_next_receive {:event, 3} 
    assert_next_receive {:event, 2} 
    end 
end 

出力：

. 

    1) test should fail (MTest) 
    test/m_test.exs:29 
    match (=) failed 
    code: {:event, 3} = message 
    right: {:event, 2} 
    stacktrace: 
     test/m_test.exs:32: (test) 



Finished in 0.05 seconds 
2 tests, 1 failure 

Randomized with seed 351622