Flash CS4 - コンポーネントインスペクタ、プロパティは常にnullですか？

Question

私はFlash CS4で小さなコンポーネントを作成しました。MyCompシンボルをそれぞれのMyCompクラスに関連付けました。

package { 
    import flash.display.MovieClip; 

    public class MyComp extends MovieClip 
    { 
     public function MyComp() 
     { 
      trace(this.test); 
     } 

     private var _test:String; 

     [Inspectable(defaultValue="blah")] 
     public function get test():String 
     { 
      return this._test; 
     } 

     public function set test(v:String):void 
     { 
      this._test = v; 
     } 
    } 
} 

私はテストFLAにコンポーネントをドラッグ

は、コンポーネントのプロパティは、すべての検査可能[]メタタグあたりとして表示され、次のようMyComp.as内のコードが見えます。しかし、コンポーネントインスペクタでプロパティを設定すると、コンポーネントインスペクタの説明にもかかわらず、値は常にnullになります。

たとえば、testをトレースすると、常にnullが出力されますか？

実行時にコンポーネントインスペクタの値をコンポーネントに反映させるにはどうすればよいですか？

Answer 1

コンポーネントと検査可能なプロパティの操作の順序はちょっと難しいかもしれません。キース・ピーターズ（Bit-101）はa nice overview of the problems with inspectable getters and settersを書いた。

特に、コンストラクタは、設定されている検査可能プロパティの前に呼び出されるという問題があります。この問題を回避するには、コンストラクタがEXIT_FRAMEイベントのリスナーを設定するようにしてください。これは、他のすべてが完了した直後に、同じフレームで実行されます。あなたはちょうどこのようなテキスト文字列「exitFrameの」、使用することができます

package { 

    import flash.display.MovieClip; 
    import flash.events.Event; 

    public class SampleComponent extends MovieClip { 

     private var _foo:Number; 

     public function SampleComponent() { 
      trace("SampleComponent: constructor"); 
      addEventListener(Event.EXIT_FRAME, onReady); 
     } 

     [Inspectable] 
     public function get foo():Number { 
      trace("SampleComponent: get foo: " + _foo); 
      return _foo; 
     } 

     public function set foo(value:Number):void { 
      trace("SampleComponent: set foo: " + value); 
      _foo = value; 
     } 

     private function onReady(event:Event):void { 
      trace("SampleComponent: ready!"); 
      removeEventListener(Event.EXIT_FRAME, onReady); 
     } 
    } 
} 

Answer 2

：たとえば

addEventListener("exitFrame", onExitFrame); 

イベントが発生し、Eventクラスがちょうど定義が欠落しているようです。