特定の方法でテーブルを転記する方法

Question

これはいくつかのデータ例です。実際のデータはより複雑で、他のフィールドと約40000回の観測値と最大180個のid値を持ちます（転置テーブルでは360行ありますが、 ）[OK]をthatsの：

Data have; 
input lastname firstname $ value; 
datalines; 
miller george 47 
miller george 45 
miller henry 44 
miller peter 45 
smith peter 42 
smith frank 46 
; 

run; 

と私はそれがこのように移調したいので、私は姓を持って、その後、姓に一致するerveryラインのためのFirstNameおよび値を交互に。

Lastname Firstname1 Value1 Firstname2 value2 Firstname3 Value3 firstname4 value4 
miller  george  47  george  45  henry  44  peter  45 
smith  peter  42  frank  46 

私はprocの転置とのビットを試してみましたが、私は上記の私はそれをしたい正確な方法を、テーブルを構築することができませんでした： データが欲しいです。私はちょうどその方法（実際のデータはより複雑で他のフィールドと同じです）が必要なテーブルを必要としますので、他のレイアウトのテーブルを作成することを提案してください。

Answer 1

proc summaryはこれを行うのに非常に有用な機能を持っています。idgroupあなたは姓ごとにいくつの値があるかを指定する必要があるので、最大数を計算するステップが含まれています。

Data have; 
input lastname $ firstname $ value; 
datalines; 
miller george 47 
miller george 45 
miller henry 44 
miller peter 45 
smith peter 42 
smith frank 46 
; 
run; 

/* get frequency count of lastnames */ 
proc freq data=have noprint order=freq; 
table lastname/out=name_freq; 
run; 

/* store maximum into a macro variable (first record will be the highest) */ 
data _null_; 
set name_freq (obs=1); 
call symput('max_num',count); 
run; 

%put &max_num.; 

/* transpose data using proc summary */ 
proc summary data=have nway; 
class lastname; 
output out=want (drop=_:) 
      idgroup(out[&max_num.] (firstname value)=)/autoname; 
run;