Excel VBA xlsxファイルをフォルダから書き込みパスなし

Question

変数を使用してパスを書き込まずにExcel xlsxファイルを開きたいとします。私は理由を知っていませんが、うまくいきません。私は、メインのブックと、xlsxを開く別の1つのフォルダを持っています。私はそれをUnionWBと名づけたい。私は誰かが助けることができればすばらしいだろう。

Private Sub cmdStartMonth_Click() 
    'Optimize Macro Speed 
    Application.ScreenUpdating = False 
    Application.EnableEvents = False 
    'Analyze month by selecting 
    Dim myPath As String 
    Dim myFile As String 
    Dim UnionWB As Workbook 
    Dim MonthName As String 
    MonthName = ListMonth.Value 
    myExtension = "*.xlsx*" 
    Set UnionWB = Workbooks.Open(ThisWorkbook.Path & myExtension) 

    Application.ScreenUpdating = True 
    Application.EnableEvents = True 
    End Sub 

設定UnionWB = Workbooks.Open（ThisWorkbook.Path & myExtension）

Answer 1

ここで役立つかもしれないいくつかの例を示します。

最初は、正しいファイルを選択するように求め、その後、それを開きます：

Public Sub Test() 

    Dim sWrkbkPath As String 
    Dim UnionWB As Workbook 

    sWrkbkPath = GetFile(ThisWorkbook.Path) 
    If sWrkbkPath <> "" Then 
     Set UnionWB = Workbooks.Open(sWrkbkPath) 
     MsgBox UnionWB.Name 
    End If 

End Sub 

Function GetFile(Optional startFolder As Variant = -1) As Variant 
    Dim fle As FileDialog 
    Dim vItem As Variant 
    Set fle = Application.FileDialog(msoFileDialogFilePicker) 
    With fle 
     .Title = "Select your Union Workbook" 
     .AllowMultiSelect = False 
     .Filters.Add "My Union Workbook", "*.xlsx", 1 
     If startFolder = -1 Then 
      .InitialFileName = Application.DefaultFilePath 
     Else 
      If Right(startFolder, 1) <> "\" Then 
       .InitialFileName = startFolder & "\" 
      Else 
       .InitialFileName = startFolder 
      End If 
     End If 
     If .Show <> -1 Then GoTo NextCode 
     vItem = .SelectedItems(1) 
    End With 
NextCode: 
    GetFile = vItem 
    Set fle = Nothing 
End Function 

第2の方法は、あなただけはThisWorkbookと同じフォルダ内の単一のxlsxファイルを持っていると仮定し、最初に見つかったファイルを開きます：

Public Sub OpenOnlyXLSXInFolder() 
    Dim sWrkbkPath As String 
    Dim UnionWB As Workbook 
    sWrkbkPath = Dir$(ThisWorkbook.Path & "\*.xlsx") 

    'Only expecting a single file so no need to loop. 
    If sWrkbkPath <> "" Then 
     Set UnionWB = Workbooks.Open(ThisWorkbook.Path & "\" & sWrkbkPath) 
     MsgBox UnionWB.Name 
    End If 

End Sub