複数のワークシートのセル範囲のゼロを非特定のワークシート名またはワークシート数で置き換えます。

Question

複数のワークシートにわたる特定の範囲でvalue = 0のセルをクリアしたいとします。ワークシートの数と名前は、マクロが実行されるたびに異なります。これは私が思いついたものですが、うまくいきません。

' 
' REMOVEZERO_KVEMoxyModel Macro 
' 
' 

Sub REMOVEZERO_KVEMoxyModel() 


    Dim ws As Worksheet 
    For Each ws In ActiveWorkbook.Worksheets 
    Call RemoveZeros 


End Sub 

Sub RemoveZeros() 


    For Each cell In Range("I3:I500") 
    If cell.Value = "0" Then cell.Clear 

End Sub 

Answer 1

以下のコードを試してください：ActiveWorkbookのすべてのワークシートをループします。この例では、Sheet.Name = "Sheet1"またはSheet.Name = "Sheet2"（Select Caseを使用している場合）は、内部に入り、指定したRangeからすべての「0」をクリアします。

コード

Option Explicit 

Sub REMOVEZERO_KVEMoxyModel() 

Dim ws As Worksheet 

For Each ws In ActiveWorkbook.Worksheets 
    Select Case ws.Name 
     ' only run the clear "0" cells in "Sheet1" and "Sheet2" >> modify according to your needs 
     Case "Sheet1", "Sheet2" 
      Call RemoveZeros(ws) 

    End Select 
Next ws 

End Sub 

Sub RemoveZeros(sht As Worksheet) 

Dim cell As Range 

For Each cell In sht.Range("I3:I500") 
    If cell.Value = "0" Then cell.ClearContents 
Next cell 

End Sub 

編集1：すべてのワークシートのための "0" セル（それが必要ないだとしてSelect Case ws.Nameを削除）をクリア

Sub REMOVEZERO_KVEMoxyModel() 

Dim ws As Worksheet 

For Each ws In ActiveWorkbook.Worksheets 
    Call RemoveZeros(ws)    
Next ws 

End Sub