コンパイル時に知られていないインターフェースへのGroovyの強制

Question

いくつかの時間前に私はどのようにしてto make a class implement an interface that it doesn't implement by declarationを尋ねました。

一つの可能​​性はas -coercionです：

interface MyInterface { 
    def foo() 
} 

class MyClass { 
    def foo() { "foo" } 
} 

def bar() { 
    return new MyClass() as MyInterface 
} 


MyInterface mi = bar() 
assert mi.foo() == "foo" 

今、私はそれを使用しようとすることを、私はコンパイル時に必要とされているインタフェースを知りません。私はこのようなジェネリック使用してみました：

interface MyInterface { 
    def foo() 
} 

class MyClass { 
    def foo() { "foo" } 
} 

class Bar { 
    public static <T> T bar(Class<T> type) { 
     return new MyClass() as T 
    } 
} 


MyInterface mi = Bar.bar(MyInterface.class) 
assert mi.foo() == "foo" 

をしかし、それは、次の例外が発生します：

Cannot cast object 'MyClass@5c4a3e60' with class 'MyClass' to class 'MyInterface' 

私は実行時にのみ知られているインターフェイスに強制できますか？

Answer 1

interface MyInterface { 
    def foo() 
} 

interface AnotherInterface { 
    def foo() 
} 

class MyClass { 
    def foo() { "foo" } 
} 

class Bar { 
    static <T> T bar(Class<T> type) { 
     new MyClass().asType(type) 
    } 
} 


MyInterface mi = Bar.bar(MyInterface) 
assert mi.foo() == "foo" 

AnotherInterface ai = Bar.bar(AnotherInterface) 
assert ai.foo() == "foo"