SAS開始日と終了日が与えられた最初の35日後に各30日間の日付を知る必要があります

Question

2つの日付、開始日と終了日が与えられています。

私は最初の35日間の日付を知りたいと思っています。その後、それぞれ30日間の期間を知りたいと思います。

私は持っています。

start  end 
22-Jun-15 22-Oct-15 
9-Jan-15 15-May-15 

希望します。

start  end   tik1  tik2  tik3  tik4 
22-Jun-15 22-Oct-15 27-Jul-15 26-Aug-15 25-Sep-15 
9-Jan-15 15-May-15 13-Feb-15 15-Mar-15 14-Apr-15 14-May-15 

私は日付の計算に問題はありませんが、実際の問題は変数を作成して名前を増やすことです。その文脈で説明する方が簡単かもしれないと思ったので、私はすべての問題を含めることに決めました。

Answer 1

次のロジックを経由して問題を解決することができます：列の

1）の決定数が追加されます。

2）の要件

data test; 
input start end; 
informat start date9. end date9.; 
format start date9. end date9.; 
datalines; 
22-Jun-15 22-Oct-15 
09-Jan-15 15-May-15 
; 
run; 

/*******Determining number of columns*******/ 
data noc_cal; 
set test; 
no_of_col = floor((end-start)/30); 
run; 
proc sql; 
select max(no_of_col) into: number_of_columns from noc_cal; 
run; 

/*******Making an array where 1st iteration(tik1) is increased by 35days whereas others are incremented by 30days*******/ 
data test1; 
set test; 
array tik tik1-tik%sysfunc(COMPRESS(&number_of_columns.)); 
format tik: date9.; 
tik1 = intnx('DAYS',START,35); 
do i= 2 to %sysfunc(COMPRESS(&number_of_columns.)); 
tik[i]= intnx('DAYS',tik[i-1],30); 
if tik[i] > end then tik[i]=.; 
end; 
drop i; 
run; 

代替方法（あなたがPROCのSQLを使用したくない包み）

data test; 
input start end; 
informat start date9. end date9.; 
format start date9. end date9.; 
datalines; 
22-Jun-15 22-Oct-15 
09-Jan-15 15-May-15 
; 
run; 

/*******Determining number of columns*******/ 
data noc_cal; 
set test; 
no_of_col = floor((end-start)/30); 
run; 

proc sort data=noc_cal; 
by no_of_col; 
run; 

data _null_; 
set noc_cal; 
by no_of_col; 
if last.no_of_col; 
call symputx('number_of_columns',no_of_col); 
run; 

/*******Making an array where 1st iteration(tik1) is increased by 35days whereas others are incremented by 30days*******/ 
data test1; 
set test; 
array tik tik1-tik%sysfunc(COMPRESS(&number_of_columns.)); 
format tik: date9.; 
tik1 = intnx('DAYS',START,35); 
do i= 2 to %sysfunc(COMPRESS(&number_of_columns.)); 
tik[i]= intnx('DAYS',tik[i-1],30); 
if tik[i] > end then tik[i]=.; 
end; 
drop i; 
run; 

マイ出力列ごとの値を計算する：

> **start |end  |tik1  | tik2  |tik3  |tik4** 
> 22Jun2015 |22Oct2015 |27Jul2015| 26Aug2015|25Sep2015|  
> 09Jan2015 |15May2015 |13Feb2015| 15Mar2015|14Apr2015|14May2015 

Answer 2

私は長い垂直構造を好む傾向があります。私はそれに近づく：

data want; 
    set have; 
    tik=start+35; 
    do while(tik<=end); 
    output; 
    tik=tik+30; 
    end; 
    format tik mmddyy10.; 
run; 

本当にそれが必要な場合は、そのデータセットを2番目のステップで転記することができます。