Moose：オブジェクト - >ループを介した属性の配列

Question

私はPerl Mooseを使い慣れていません。この単純な作業を達成しようとしています。私は私のムースクラス「TestObject」が定義されている：

私は「TestObjects」の配列から直接属性「識別子」にアクセスしようとしている別のスクリプトで

package TestObject; 
use Moose; 
use namespace::autoclean; 

has 'Identifier' => (is =>'ro',isa=>'Str'); 

around BUILDARGS => sub 
{ 
    my $orig = shift; 
    my $class = shift; 

    if (@_ == 1 && ! ref $_[0]) { 
     return $class->$orig(Identifier => $_[0]); 
    } 
    else { 
     return $class->$orig(@_); 
    } 
}; 
__PACKAGE__->meta->make_immutable; 
1; 

：これは「doesnの

use TestObject; 
use experimental 'smartmatch'; 
my @aArray1=(TestObject->new("z003"),TestObject->new("t302"),TestObject->new("r002")); 
my $sIdent="t302"; 
if($sIdent~~@aArray1->Identifier) 
{ 
    print "Element with Identifier".$sIdent." found."; 
} 

仕事。私はこのような回避策を実装することができます：

my @aIdent=(); 
foreach my $sObject(@aArray1) 
{ 
    push(@aIdent,$sObject->Identifier); 
} 
if($sIdent~~@aIdent) 
{ 
    print "Element with Identifier".$sIdent." found."; 
} 

しかし、それは最もエレガントな解決策ではないようです。この問題を解決する最も洗練されたソリューションは何ですか？

Answer 1

smartmatchオペレータではこれを行わないでください。実験的な理由から、将来のPerlのバージョンから削除されるか、以前のように動作する方法を変更する可能性があります。

代わりに、これは簡単なgrepで実現できます。

my @aArray1 = ( 
    TestObject->new("z003"), 
    TestObject->new("t302"), 
    TestObject->new("r002"), 
); 

my $sIdent = "t302"; 
if (grep { $_->Identifier eq $sIdent } @aArray1) { 
    print "Element with Identifier" . $sIdent . " found."; 
} 

あなたはそれが少し短くなるようにしたい場合は、first from List::Utilを使用することができます。これは、最初の試合を見直すのが止まるので少し速くなります。

use List::Util 'first'; 
my @aArray1 = ( 
    TestObject->new("z003"), 
    TestObject->new("t302"), 
    TestObject->new("r002"), 
); 

my $sIdent = "t302"; 
if (first { $_->Identifier eq $sIdent } @aArray1) { 
    print "Element with Identifier" . $sIdent . " found."; 
} 

---

あなたのコード上のアドバイスのいくつかの単語：

• は今までオブジェクトを持つクラスの任意の名前を付けるしないでください。それはあなた、将来あなたとメンテナンスを混乱させるでしょう。 クラスとオブジェクトの違いを理解できない場合は、それをお読みください。
• Perlの変数名と関数は、慣例により常に小文字で記述されており、スネークケースを使用しています。キャメルケースはパッケージ名のために予約されています。