VB.net mySQLを呼び出すたびに画面を読み込み

Question

実際に読み込み画面ではない読み込み画面を作成しました。その上に「読み込み中」のあるピクチャボックスを表示しているようです。

別の方法があるのだろうかと思っていました。私の仕事はちょっとうんざりしているから。

私は、クエリ、成功か

Loading.hide() 
Panel_Main.Enable = True 

ロードした後、この

Loading.show() 
Panel_Main.Enable = False 

を行うと、Panel_Mainが同じ親を持つクエリを得ました。

ユーザーが別のボタンをクリックして別のクエリを要求するのを防ぐために、読み込み画面を置く最善の方法は何ですか？

編集： また、モーダルフォームを開くためにshowdialog（）を作成しました。今問題は、クエリが成功を返すかどうかの後にそのモーダルフォームを閉じる方法ですか？

クエリが

form2.close() 

このdidntの仕事を返した後、私は、クエリ

Dim form2 as New Form2 
form2.showdialog() 'this opens the new modal form 

そしてこれを得たとき、私はこれを使用していました。

私もForm2の

Public sub closeMe() 
    Me.close() 
End sub 

でパブリックサブを作った後のForm1

form2.closeMe() 

Answer 1

でこれを呼び出すことはここでは方法がで実行されているときにモーダルダイアログを表示する方法の例です呼び出しフォーム。トリックは、ダイアログを取得してメソッドを呼び出すことで、メソッドが完了して自身を閉じることができることも認識できるようにすることです。

ダイアログ：ダイアログが作成されると

'The method to execute while the dialogue is displayed. 
Private action As [Delegate] 

'The arguments to the method to be executed. 
Private args As Object() 

'The result of the executed method, if there is one, can be retrieved from here. 
Public Property Result As Object 

Public Sub New(action As [Delegate], ParamArray args As Object()) 
    ' This call is required by the designer. 
    InitializeComponent() 

    ' Add any initialization after the InitializeComponent() call. 
    Me.action = action 
    Me.args = args 
End Sub 

Private Sub Form2_Shown(sender As Object, e As EventArgs) Handles Me.Shown 
    'Make sure that the dialogue is displayed fully. 
    Refresh() 

    'Execute the method once the dialogue is displayed. 
    Result = action.DynamicInvoke(args) 

    'Close the dialogue when the method completes. 
    Close() 
End Sub 

、それはすなわち、メソッドへの参照、およびそのメソッドの引数のリスト、デリゲートを取ります。ダイアログが表示されると、その代理人が呼び出され、メソッドが実行されます。メソッドが完了すると、結果はパブリックプロパティで利用可能になり、その後閉じます。

発信者：例で

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click 
    Using dialogue As New Form2(New Func(Of Integer, String)(AddressOf GenerateRandomText), 10) 
     dialogue.ShowDialog() 

     Dim result = CStr(dialogue.Result) 

     MessageBox.Show(result) 
    End Using 
End Sub 

Private Function GenerateRandomText(length As Integer) As String 
    Const chars = "abcdefghijklmnopqrstuvwxyz" 

    Dim rng As New Random 
    Dim result = String.Empty 

    For i = 1 To length 
     result &= chars(rng.Next(chars.Length)) 

     'Simulate a long-running task. 
     Thread.Sleep(500) 
    Next 

    Return result 
End Function 

、発信者はランダム小文字のStringを生成する方法を含みます。ダイアログを表示し、そのメソッドを呼び出してダイアログボックスにString（10文字）を作成するように指示します。ダイアログが閉じられると、ダイアログボックスからStringが取得され、表示されます。

Thread.Sleepコールを追加すると、少し時間がかかり、ダイアログが現れるとすぐに消えることはありません。また、UIスレッドで長時間実行されるメソッドが実行されるため、対話ペイントが正しく行われないため、ダイアログにはRefreshコールが必要です。これをすべて適切に行うには、メソッドを実際にセカンダリスレッドで呼び出す必要がありますが、それはやや複雑です。

EDIT：

あなたが対話形式にBackgroundWorkerを追加する場合は、あなたがセカンダリスレッドでメソッドを実行することができます。実行しているメソッドがUIにアクセスしていないか、スレッド間の問題がある可能性があります。

対話：

'The method to execute while the dialogue is displayed. 
Private action As [Delegate] 

'The arguments to the method to be executed. 
Private args As Object() 

'The result of the executed method, if there is one, can be retrieved from here. 
Public Property Result As Object 

Public Sub New(action As [Delegate], ParamArray args As Object()) 
    ' This call is required by the designer. 
    InitializeComponent() 

    ' Add any initialization after the InitializeComponent() call. 
    Me.action = action 
    Me.args = args 
End Sub 

Private Sub Form2_Shown(sender As Object, e As EventArgs) Handles Me.Shown 
    BackgroundWorker1.RunWorkerAsync() 
End Sub 

Private Sub BackgroundWorker1_DoWork(sender As Object, e As DoWorkEventArgs) Handles BackgroundWorker1.DoWork 
    'Execute the method on a background thread. 
    Result = action.DynamicInvoke(args) 
End Sub 

Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted 
    'Close the dialogue when the method completes. 
    Close() 
End Sub