SASデータステップが正しく動作しない場合

Question

以下のコードでは、電子メールが常に送信されます。 1は明らかに0に等しくはありませんが、まだ実行されています。私はdo部を削除しようとしましたが、それでも同じ問題が発生します。

data _null_; 
set TestTable; 
if 1 = 0 then do; 
    file sendit email 
    to=("email@gmail.com") 
    subject="Some Subject Line"; 
end;  
run; 

Answer 1

file文は実行文とみなされる（したがって際に虚偽の陳述ifの後ろに実行すべきではない）、それは本当に全く真実ではないですが。 SASはコンパイル中にfile文を見て、書き込み先のファイルを作成する必要があることを知っているので、ややコンパイル時です。それはここで起こっていることです - SASは、コンパイラの活動の結果としてファイル（この場合は電子メール）を作成し、実際には何も投入しませんが、終わりにはまだ電子メールを持っています。

同じことが他のファイルで発生 - そのように：

data _null_; 
    set sashelp.class; 
    if 0 then do; 
     file "c:\temp\test_non_zero.txt"; 
     put name $; 
    end; 
run; 

空白のファイルがそのコードによって作成されます。

条件付きで電子メールを送信する必要がある場合は、電子メールコードをマクロにラップし、そのマクロをcall executeなどを使用してデータセットから呼び出すことをおすすめします。ように：

%macro write_email(parameters); 
data _null_; 
    file sendit email 
    to=("email@gmail.com") 
    subject="Some Subject Line"; 
run; 
%mend write_email; 

data _null_; 
    set TestTable; 
    if 0 then do; 
    call execute('%write_email(parameters)'); 
    end; 
run; 

Answer 2

メッセージを中止するには電子メールディレクティブを使用してください。 http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002058232.htm

data _null_; 
    file sendit email to=("email@gmail.com") subject="Some Subject Line"; 
    if nobs=0 then put '!EM_ABORT!'; 
    set TestTable nobs=nobs; 
    .... 
run;