VBAコードパフォーマンスの問題

Question

VBAマクロを使用して、列Aのテキスト文字を検索する列を挿入しています。 コードが正しく実行されています。ただし、クラッシュするようなファイルが表示されます。私はマクロを構築し、スムーズに動かしたいと考えています。 私のコード

コードを最適化する方法はあります：

Sheets("Annual Rec").Select 
Columns("B:B").Select 
Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove 
Selection.NumberFormat = "General" 
Range("B2:B" & Range("A" & Rows.Count).End(xlUp).Row).Formula = "=ISTEXT(RC[-1])" 
Range("B2:B" & Range("A" & Rows.Count).End(xlUp).Row).Select 
Selection.Copy 
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _ 
    :=False, Transpose:=False 
Application.CutCopyMode = False 

Answer 1

以下のコードは、あなたのものと同じですが、不要なものだけを除いてSelectとSelectionです。

Option Explicit 

Sub CopyColPasteVal() 

Application.ScreenUpdating = False 

With Sheets("Annual Rec") 
    .Columns("B:B").Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove 
    .Columns("B:B").NumberFormat = "General" 
    With .Range("B2:B" & .Range("A" & .Rows.Count).End(xlUp).Row) 
     .Formula = "=ISTEXT(RC[-1])" 
     .Copy 
     .PasteSpecial xlPasteValues 
    End With 
    Application.CutCopyMode = False 
End With 

Application.ScreenUpdating = True 

End Sub 

Answer 2

はこれを試してみてください：

Application.ScreenUpdating = False 
'your code 
Application.ScreenUpdating = True 

そして選択文を避けるためには、彼らは非常に遅いです。